使用 xslt 更改属性的值

Question

还有许多其他问题涉及该领域，但我无法解决那里的问题

我有一个转换，它将包含多个 bean 的 Spring bean 文件拆分为一组文件，每个文件都有一个 bean

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/beans/bean" xml:space="preserve"> 
            <xsl:result-document href='{translate(normalize-space(./property[@name="name"])," ", "_")}.xml'
            doctype-public="-//SPRING//DTD BEAN//EN"
            doctype-system="http://www.springframework.org/dtd/spring-beans.dtd">
<beans>
    <xsl:copy-of select="."/>
</beans>
</xsl:result-document>
</xsl:template>
</xsl:stylesheet>

这工作正常，生成这样开头的文件：

<!DOCTYPE beans
  PUBLIC "-//SPRING//DTD BEAN//EN" "http://www.springframework.org/dtd/spring-beans.dtd">
<beans>
    <bean class="com.class.mine.Policy" name="bean1">
        <property name="name">

为了使文件看起来与最初创建的只有一个 bean 的文件相同（因为文件将被检入源代码管理，我只想要真正的差异），我想将 name="beanN" 属性更改为 @ 987654324@ 在每个文件中。请注意，通常 bean 标记可以包含附加属性以及 class 和 name 属性。

根据此处的其他答案，我没有尝试过任何方法。大多数情况下，我收到有关“无法创建其父节点是文档节点的属性节点”和“在创建包含元素的子节点后无法创建属性节点”的错误。

所以我遗漏了一些明显的东西。我需要添加什么来进行这种额外的更改？

更新：问题似乎部分与 xml:space="preserve" 有关。这可能会导致创建文本节点。删除后，我不会经常收到错误，但我仍然无法正确进行转换

（并且输出有

<beans><bean>

如何在这些标签之间获得换行符？我可以使用 indent="yes" 来格式化输出，但我真的想保留原来的输入格式，只在我必须的地方进行更改）

更新：我的许多尝试之一。这个运行，但基本上是一个身份转换。 result-doc 被注释掉以使调试更容易。我真的不明白 xsl:attribute 是如何工作的，所以一个体面的解释可能会有所帮助。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="beans/bean"> 
<!--             <xsl:result-document href='{translate(normalize-space(./property[@name="name"])," /", "_+")}.xml'
            doctype-public="-//SPRING//DTD BEAN//EN"
            doctype-system="http://www.springframework.org/dtd/spring-beans.dtd"
            omit-xml-declaration="no"> -->
<beans>
<xsl:apply-templates select="bean"/>
<xsl:copy-of select="." /> 
</beans>
<!-- </xsl:result-document> -->
</xsl:template>
 <xsl:template match="bean/@*">
      <xsl:copy>
          <xsl:attribute name="name">myvalue</xsl:attribute>
           <xsl:copy-of select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

Answer 1

如果您想要特定的缩进，那么您必须自己插入相关的换行符和空格：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" omit-xml-declaration="yes"/>

  <xsl:template match="/">
    <xsl:apply-templates select="beans/bean" />
  </xsl:template>

  <xsl:template match="bean"> 
    <xsl:result-document href='{translate(normalize-space(./property[@name="name"])," /", "_+")}.xml'
            doctype-public="-//SPRING//DTD BEAN//EN"
            doctype-system="http://www.springframework.org/dtd/spring-beans.dtd"
            omit-xml-declaration="no">
      <xsl:text>&#10;</xsl:text><!-- newline after the DOCTYPE -->
      <beans>
        <xsl:text>&#10;    </xsl:text><!-- newline and four spaces -->
        <bean>
          <xsl:copy-of select="@*" />
          <xsl:attribute name="name">bean0</xsl:attribute>
          <xsl:copy-of select="node()" />
        </bean>
        <xsl:text>&#10;</xsl:text><!-- newline between </bean> and </beans> -->
      </beans>
    </xsl:result-document>
  </xsl:template>
</xsl:stylesheet>

对于重命名：

        <bean>
          <xsl:copy-of select="@*" />
          <xsl:attribute name="name">bean0</xsl:attribute>
          <xsl:copy-of select="node()" />
        </bean>

首先我从原始bean 标记中复制所有属性（可能包括name），然后创建一个（另一个）name 属性，该属性将覆盖已复制的属性，然后最后复制所有子节点原始bean 元素（包括元素、cmets 和 文本节点，因此将保留原始缩进）。