如何让我的程序的第二个实例将控制权传递回第一个实例？

Question

我已经用 Delphi XE3 创建了一个应用程序。 我的应用程序有一个托盘图标（我为此使用 TCoolTrayIcon），所以当用户最小化它时，任务栏上没有图标，而只有托盘图标。

为了避免我的应用程序不止一个，我使用以下代码：

procedure CreateMutexes(const MutexName: String);
const
  SECURITY_DESCRIPTOR_REVISION = 1;
var
  SecurityDesc: TSecurityDescriptor;
  SecurityAttr: TSecurityAttributes;
  MutexHandle: THandle;
begin
  InitializeSecurityDescriptor(@SecurityDesc, SECURITY_DESCRIPTOR_REVISION);
  SetSecurityDescriptorDacl(@SecurityDesc, True, nil, False);
  SecurityAttr.nLength := SizeOf(SecurityAttr);
  SecurityAttr.lpSecurityDescriptor := @SecurityDesc;
  SecurityAttr.bInheritHandle := False;
  MutexHandle := CreateMutex(@SecurityAttr, False, PChar(MutexName));

  if MutexHandle <> 0 then
    begin
      if GetLastError = ERROR_ALREADY_EXISTS then
        begin
          MessageBox(0, 'You cannot start more than one instance of ContLab.'
                      + #13#10 + 'Use the instance has already started.',
                       'ContLab', mb_IconHand);

          CloseHandle(MutexHandle);
          Halt;
        end
    end;

  CreateMutex(@SecurityAttr, False, PChar('Global\' + MutexName));
end;

这样，当用户启动应用程序 2 次时，他会收到一条错误消息，并且第二个实例被终止。

现在我不想显示错误消息，而是打开应用程序第一个实例的主窗体并终止第二个实例。

有可能吗？

Answer 1

您需要向其他应用程序发送一条消息以请求它显示自己。

首先你需要找到另一个应用程序的主窗口。有很多方法可以做到这一点。例如，您可以使用FindWindow。或者您可以使用EnumWindows 枚举顶级窗口。通常，您会检查匹配的窗口文本和/或类名。

一旦你找到了另一个实例的主窗口，你需要让它能够将自己设置为前景窗口。您需要致电AllowSetForegroundWindow。

var
  pid: DWORD;
....
GetWindowThreadProcessId(hwndOtherInstance, pid);
AllowSetForegroundWindow(pid);

然后向窗口发送用户定义的消息。例如：

const
  WM_RESTOREWINDOW = WM_APP;
....
SendMessage(hwndOtherInstance, WM_RESTOREWINDOW, 0, 0);

最后，您的其他实例的主窗体需要监听此消息。

type
  TMainForm = class(TForm)
  ....
  protected
    procedure WMRestoreWindow(var Message: TMessage); message WM_RESTOREWINDOW;
  ....
  end;

当它遇到消息时它必须这样做：

procedure TMainForm.WMRestoreWindow(var Message: TMessage);
begin
  inherited;
  Visible := True;
  Application.Restore;
  Application.BringToFront;
end;

---

我对您的互斥锁处理代码有点怀疑。我不明白对安全属性的需求，因为您是在本地命名空间中创建它。但随后我看到对CreateMutex 的第二次调用忽略了返回值，但在全局命名空间中创建了一个对象。