【问题标题】:Sorting a memo in Delphi在 Delphi 中对备忘录进行排序
【发布时间】:2013-10-25 14:00:10
【问题描述】:

我必须在 Delphi 6 中为我的学校制作高分备忘录。 有没有办法按数字或字母对 MemoLines 进行排序?

我使用 4 个 Tedits 和 1 个 TMemo。 如果游戏结束,我的代码会检查谁得分最高。 这是检查 Player1 是否比 player2 得分更高的方法:

if in1>p2in1 then begin
  highscore.naammemo.Lines.Add(Speler1.Caption);
  highscore.saldomemo.Lines.Add(Saldo1.Text);
end;

如何为 TMemo 创建代码以对每场比赛的最高分进行排序?

【问题讨论】:

  • 我认为您应该考虑创建数据对象并对数据对象进行排序。然后您应该将数据对象(已经排序)打印到字符串列表中。您陷入了“字符串类型”的不良做法,即仅使用内置数据类型(尤其是字符串),您应该考虑创建自己的记录或类。

标签: delphi delphi-6 memo


【解决方案1】:

我认为最简单的方法是这样的:

  1. 将备忘录中的内容传输到TStringList 实例。
  2. 在TStringList 实例上调用CustomSort,传递适当的排序比较函数。
  3. 将内容传回备忘录。

第 1 步和第 3 步是对Assign 的简单调用。所以第一步是:

StringList.Assign(Memo.Lines);

第 3 步将是:

Memo.Lines.Assign(StringList);

第 2 步比较棘手。你必须提供这种类型的比较函数:

TStringListSortCompare = function(List: TStringList; 
  Index1, Index2: Integer): Integer;

您的函数将如下所示:

function MySortCompare(List: TStringList; Index1, Index2: Integer): Integer;
begin
  Result := MyCompareStrings(List[Index1], List[Index2]);
end;

其中MyCompareStrings 是一个根据您的规则比较两个字符串的函数。该函数的返回值遵循比较函数的通常约定。负数表示小于,正数表示大于,零表示相等。

当然,如果你愿意,你可以直接将逻辑内联到MySortCompare。

【讨论】:

  • 非常感谢您的出色回答,但我不明白我必须将步骤 1-3 的代码放在我的项目中的什么位置。
  • 好吧,这是你的代码,不是我的。鉴于只有您可以看到您的代码,您几乎不能指望我们准确地告诉您要写什么以及在哪里写。您询问了如何根据一些自定义顺序对备忘录进行排序。在代码中需要执行此操作的位置处,在步骤 1-3 中进行拼接。你应该关注的是理解。
  • 我期待你的 slicker way 大卫... ;-) 顺便说一句 +1
  • @NGLN 看起来我对更流畅的方式的期望是不现实的! ;-) 你有大象的记忆。我得小心我在这里说的话,它会回来咬我的!! :-)
【解决方案2】:

这里有一些示例代码可以让您试验排序。它在每一行使用一个文本值和一个数字,由制表符分隔 (#9)。每个按钮单击处理程序的开头都有代码,将文本重置为相同的起始值,因此您可以看到效果。第一个按钮 (btnNameSort) 使用标准 TStringList.Sort 按文本值排序,第二个按钮 (btnScoreSort) 使用 TListSortCompare 自定义排序函数按数值排序。

// Simply uses TStringList.Sort to sort in the default (alpha) order
procedure TForm1.btnNameSortClick(Sender: TObject);
var
  SL: TStringList;
begin
  InitMemoLines;
  SL := TStringList.Create;
  try
    Memo1.Lines.BeginUpdate;
    try
      SL.Assign(Memo1.Lines);
      SL.Sort;
      Memo1.Lines.Assign(SL);
    finally
      Memo1.Lines.EndUpdate;
    end;
  finally
    SL.Free;
  end;
end;

// Sorts by extracting the text after the tab character on the lines
// being compared, converting to numbers, and comparing the numbers.
// Called by using SL.CustomSort in the btnScoreSortClick event
// below.
//
// NOTE: Will obviously fail if the lines don't contain a tab, or
// if the content after the tab can't be converted to a numeric.
// Neither of those cases is handled here for brevity. 
function NumberedListSort(List: TStringList; Index1, Index2: Integer): Integer;
var
  Line1, Line2: string;
  Num1, Num2: Integer;
begin
  Line1 := List[Index1];
  Line2 := List[Index2];
  Num1 := StrToInt(Copy(Line1, Pos(#9, Line1) + 1, 255));
  Num2 := StrToInt(Copy(Line2, Pos(#9, Line2) + 1, 255));
  Result := Num1 - Num2;
end;

// Calls NumberedListSort to sort by the numbers on the right end 
// of each line in the memo
procedure TForm1.btnScoreSortClick(Sender: TObject);
var
  SL: TStringList;
begin
  InitMemoLines;
  SL := TStringList.Create;
  try
    Memo1.Lines.BeginUpdate;
    try
      SL.Assign(Memo1.Lines);
      SL.CustomSort(NumberedListSort);
      Memo1.Lines.Assign(SL);
    finally
      Memo1.Lines.EndUpdate;
    end;
  finally
    SL.Free;
  end;
end;

// Calls InitMemoLines to set the starting content of the memo
procedure TForm1.FormCreate(Sender: TObject);
begin
  InitMemoLines;
end;

// Generates content of memo
procedure TForm1.InitMemoLines;
var
  i: Integer;
begin
  Memo1.Lines.Clear;
  for i := 1 to 10 do
    Memo1.Lines.Append(Format('Line ' + Chr(90 - i) + #9 + ' %d', [i]));
end;

【讨论】:

    猜你喜欢
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 2011-05-18
    • 1970-01-01
    • 1970-01-01
    • 2011-06-14
    • 1970-01-01
    • 2013-12-01
    相关资源
    最近更新 更多