如何为 Elm 中的嵌套记录创建通用更新函数答案

【问题标题】：How to make a generic update function for a nested record in Elm如何为 Elm 中的嵌套记录创建通用更新函数
【发布时间】：2016-07-23 18:24:09
【问题描述】：

在 Elm 中，我有一个具有嵌套属性的模型，例如：

model =
  { name = ""
  , disruptedFields =
    { advertising =
      { name = "Advertising"
      , checked = False
      }
    , travel =
      { name = "Travel"
      , checked = False
      }
    , utilities =
      { name = "Utilities"
      , checked = False
      }
    }
  }

disruptedFields 包含复选框的值列表。当我点击复选框时，我会向UpdateDisruptedField 发送一条更新消息，目前看起来像：

UpdateDisruptedField value ->
  let
    fieldCollection = model.disruptedFields
    field = fieldCollection.advertising
  in
    { model | disruptedFields =
      { fieldCollection | advertising =
        { field | checked = (not value) }
      }
    }

我的更新函数在field 和advertising 变量中硬编码为model.disruptedField.advertising。这对我有用，但我坚持使函数通用。

如何将记录传递到 UpdateDisruptedField 中，以便使其具有通用性？

【问题讨论】：

标签： elm

【解决方案1】：

这是具有许多输入字段的 Elm 应用程序的常见问题。有两种方法可以创建通用更新函数以减少代码重复。

使用输入标识符扩展消息以进行更新，然后使用case checkboxType of 添加另一个级别的开关，并使用所有嵌套记录处理更新。每次在模型中添加新字段时，都必须使用额外的分支来扩展更新以处理更新。
使用字典重新构建模型并以适当的通用方式处理更新。

我更喜欢第二个选项，因为更新嵌套记录是一件苦差事。

请考虑以下示例：

module Main exposing (..)

import Html exposing (div, input, text, label)
import Html.App exposing (beginnerProgram)
import Html.Events exposing (onCheck)
import Html.Attributes exposing (type', checked)
import Dict


(=>) : a -> b -> ( a, b )
(=>) a b =
    ( a, b )


main =
    beginnerProgram { model = model, view = view, update = update }


model =
    { name = ""
    , disruptedFields =
        Dict.fromList
            [ "advertising"
                => { name = "Advertising"
                   , checked = False
                   }
            , "travel"
                => { name = "Travel"
                   , checked = False
                   }
            , "utilities"
                => { name = "Utilities"
                   , checked = False
                   }
            ]
    }


type Msg
    = Check String Bool


view model =
    let
        checkbox ( key, data ) =
            label []
                [ text data.name
                , input
                    [ type' "checkbox"
                    , checked data.checked
                    , onCheck (Check key)
                    ]
                    []
                ]
    in
        div []
            (model.disruptedFields
                |> Dict.toList
                |> List.map checkbox
            )


update msg model =
    case msg of
        Check checkboxId checked ->
            let
                updateRecord =
                    Maybe.map (\checkboxData -> { checkboxData | checked = checked })

                disruptedFieldsUpdated =
                    Dict.update checkboxId
                        updateRecord
                        model.disruptedFields
            in
                { model | disruptedFields = disruptedFieldsUpdated }

请注意，我一直在使用 => 运算符使元组看起来更好。

disruptedFields 现在是一个字典，它使用String 键来识别每个复选框。

【讨论】：

【解决方案2】：

为什么不使用Dict 而不是明确列出所有字段？

【讨论】：