检查 java 版本和 java home 的脚本

Question

我是 MR 工具管理员，我需要一个批处理脚本来满足以下要求

1. 必须检查Computer > properties (right click) > Advanced system settings > Advanced > Environment Variables中是否设置了Java home。

   如果 Java 主页可用，则需要显示 "Java home is available" 否则 "Java home is not available"。

2. 它必须检查使用的java版本，如果它大于1.6.495它必须显示"Java version is too high"否则"Java version is compatible"。

目前我正在使用下面给出的脚本... 任何人都可以请帮助制作上述脚本吗？

@echo off
IF "%JAVA_HOME%" == "" (
    echo Enter path to JAVA_HOME: 
    set /p JAVA_HOME=
) ELSE (
    echo %JAVA_HOME%
)

Answer 1

试一试……

我不太确定您所说的“java home 可用”是什么意思。该脚本检查%JAVA_HOME% 指向的目录是否包含bin\java.exe。

棘手的一点是获取版本。我获取了java -version 的输出并使用FIND 来获取第一行，这类似于我系统上的java version "1.7.0_55"。 java -version 将此写入 stderr 而不是 stdout，因此错误重定向（2>& 1 将错误输出重定向到标准输出）在管道到 FIND 之前。然后将该混乱重定向到临时文件中。然后我使用SET /p 将输入从临时重定向到将输出放入变量中。

@echo off
SETLOCAL
SET TEMPFILE=%TEMP%\tmpfile
IF "%JAVA_HOME%" == "" (
    echo Enter path to JAVA_HOME:
    set /p JAVA_HOME=
) ELSE (
    echo JAVA_HOME = %JAVA_HOME%
)

IF EXIST "%JAVA_HOME%\bin\java.exe" (
    ECHO Java home is available
) ELSE ECHO Java home is not available

"%JAVA_HOME%\bin\java" -version 2>& 1 | FIND "java version" > %TEMPFILE%
SET /p VERSIONSTRING= < %TEMPFILE%
DEL %TEMPFILE%
SET MAJORVERSION=%VERSIONSTRING:~14,1%
SET MINORVERSION=%VERSIONSTRING:~16,1%
SET UPDATEVERSION=%VERSIONSTRING:~20,-1%
IF %MAJORVERSION% GTR 1 GOTO TOOHIGH
IF %MINORVERSION% GTR 6 GOTO TOOHIGH
IF %UPDATEVERSION% GTR 495 GOTO TOOHIGH
ECHO Java version is compatible.
GOTO EXIT

:TOOHIGH
ECHO Java version is too high.

:EXIT
ENDLOCAL