高阶函数内的多态性？

Question

我有一个代数数据类型，其中一些构造函数具有可比较的值，而一些构造函数则不具有。我编写了一些比较函数，它们的工作方式类似于标准的 (==) 和 (/=) 运算符，但对于没有意义的比较返回 Nothing：

data Variant = IntValue Int
             | FloatValue Float
             | NoValue

equal :: Variant -> Variant -> Maybe Bool
equal (IntValue a) (IntValue b) = Just (a == b)
equal (FloatValue a) (FloatValue b) = Just (a == b)
equal _ _ = Nothing

unequal :: Variant -> Variant -> Maybe Bool
unequal (IntValue a) (IntValue b) = Just (a /= b)
unequal (FloatValue a) (FloatValue b) = Just (a /= b)
unequal _ _ = Nothing

这行得通，但重复起来很笨拙——尤其是因为我实际上有更多的Variant 构造函数和更多的比较函数。

我想我可以将重复因素分解为一个辅助函数，该函数在比较函数上参数化：

helper :: (Eq a) => (a -> a -> Bool) -> Variant -> Variant -> Maybe Bool
helper f (IntValue a) (IntValue b) = Just (f a b)
helper f (FloatValue a) (FloatValue b) = Just (f a b)
helper _ _ _ = Nothing

equal' :: Variant -> Variant -> Maybe Bool
equal' = helper (==)

unequal' :: Variant -> Variant -> Maybe Bool
unequal' = helper (/=)

但这不起作用，因为类型变量a 显然不能在helper 的定义中同时绑定到Int 和Float； GHC 将其绑定到Float，然后在处理IntValue 的行上抱怨类型不匹配。

像(==) 这样的函数在直接使用时是多态的；有没有办法将它传递给另一个函数并让它保持多态？

Answer 1

是的，这是可能的，但仅限language extensions：

{-# LANGUAGE Rank2Types #-}

helper :: (forall a. (Eq a) => (a -> a -> Bool))
       -> Variant -> Variant -> Maybe Bool
helper f (IntValue a) (IntValue b) = Just (f a b)
helper f (FloatValue a) (FloatValue b) = Just (f a b)
helper _ _ _ = Nothing

forall a. 听起来像什么； a 在括号内被普遍量化，在括号外超出范围。这意味着 f 参数必须在所有类型 a 上都是多态的，这些类型是 Eq 的实例，这正是您想要的。

这里的扩展被称为“rank 2”，因为它允许在最外层范围内使用常规样式的多态，以及此处示例中的多态参数。要进一步嵌套，您需要扩展名RankNTypes，它具有相当的自我描述性。

顺便说一句，关于更高级别的多态类型——请记住，forall 是实际将变量绑定到类型的东西；事实上，你可以认为它们的行为很像 lambda。当您将这样的函数应用于具有具体类型的事物时，参数的类型会隐式地由 forall 绑定以用于该用途。例如，如果您尝试使用其类型被该函数外部的内部forall 绑定的值，就会出现这种情况；值的类型超出范围，这使得做任何明智的事情变得困难（正如您可能想象的那样）。