读取文件并修改

Question

我正在尝试处理数据流。

首先我将一个文本文件添加到我的脚本中。

文本文件是这样的：

pierwsza linia  koniec
druga linia lorem1 koniec lorem1 lorem1
trzecia linia lorem1 koniec lorem1
czwarta linia lorem1 koniec
piata liniakoniec
szosta linia lorem1 koniec

我想要实现的是一个包含所有行但只有第一次出现 lorem1 的文件。

所以预期的结果应该是这样的

pierwsza linia  koniec
druga linia lorem1 koniec
trzecia linia koniec
czwarta linia koniec
piata liniakoniec
szosta linia koniec

我的脚本是这样的

#!/usr/bin/perl -pi

use strict;

my $line = $_;
my $loremcn;

while ( $line = <> ) {

    #if ( $line =~ m/lorem1/ )

    foreach ( $line =~ m/lorem1/gi ) {

        $loremcn++;

        if ( $loremcn >= 2 ) {
            $line =~ s/lorem1//gi;
        }

        print "$loremcn\n";
        print $line;

        chomp $line;
    }
}

但结果只是第一行（因为脚本开头的-pi）文本。

该脚本正确计算 lorem1 (7) 的出现次数，但由于 /g 选项，它会删除所有 lorem1 出现次数（它不会单独留下第一个）。

最后，如何将整个更正后的文本打印到屏幕上？

更新

我在其中一个答案上写了这个重要的评论：

在 RL 中，我不能按照你的方式来做。整个练习是找到一种方法来处理流数据。在真实情况下，整个数据不是来自打开的文本，而是从 SAP 流式传输到打印机的假脱机数据。并且这些数据需要在送到打印机的途中进行更正

Answer 1

#!/usr/bin/perl 
use strict;
use warnings;

# lorem counter
my $loremcn = 0;
# loop over the input file
while (my $line = <> ) {
    # if line contains lorem1 but not alorem1 or lorem12
    if ($line =~ /\blorem1\b/i) {
        # not the first time. counter > 0
        if ($loremcn) {
            # remove all lorem1 and optional leading horizontal spaces
            $line =~ s/\h*\blorem1\b//gi;   # comment for syntax color /
        # first time lorem1 is encountered (counter == 0)
        } else {
            # remove all lorem1 but the first
        while ($line =~ s/
                            (\blorem1\b.*?)     # first lorem1 in the line followed by 0 or more anycharacter
                            \blorem1\b          # subsequent lorem1
                            /$1/gix             # replace with the first group (i.e. the first lorem1
            ) { 1;}
        }
        # incement counter
        $loremcn++;
    }
    # print the modified line
    print $line;
}

输出：

pierwsza linia  koniec
druga linia lorem1 koniec  
trzecia linia koniec
czwarta linia koniec
piata liniakoniec
szosta linia koniec

用法：

perl test.pl inputfile > outputfile

Answer 2

一个使用perl的班轮：

您可以保留所有内容直到第一个 lorem，然后删除此之后的所有 lorem

 $perl -pe "undef $/;s/^.*?\blorem1\K|\blorem1//g" lorem.txt

• \b - 用于确定边界。
• .*?- 非贪婪匹配。将所有内容与第二个 lorem 匹配
• \K - 丢弃任何以前使用过的字符。因此从第二个 lorem 删除到最后

输出

pierwsza linia  koniec
druga linia lorem1 koniec
trzecia linia  koniec
czwarta linia  koniec
piata liniakoniec
szosta linia  koniec

现在如果你想把它保存在另一个文件中，你可以这样做：

perl -pe "undef $/;s/^.*?\blorem1\K|\blorem1//g" lorem.txt > new_file.txt

如果您的perl 版本不支持\K，您可以使用：

 perl -pe "undef $/;s/(^.*?\blorem1)|\blorem1/$1/g" lorem.txt

Answer 3

不就是这样吗？

my $seen;
while (<>) {
  s/\blorem1\b//g if $seen;
  $seen = 1 if /\blorem1\b/;
  print;
}

更新：好吧，这比我最初想象的要复杂一些。但这似乎可以满足您的要求：

#!/usr/bin/perl

use strict;
use warnings;

my $seen;

while (<>) {
  if ($seen) {
    s/\blorem1\b//g;
  } else {
    1 while s/(?<=\blorem1\b)(.*)\blorem1\b/$1/g;
    $seen = 1 if /\blorem1\b/;
  }
  print;
}

Answer 4

像这样使用B::Deparse 运行您的代码

perl -MO=Deparse xx.pl

给出这个结果

BEGIN { $^I = ""; }   # From -i

LINE: while (defined($_ = readline ARGV)) {


    use strict;
    my $line = $_;
    my $loremcn;
    while (defined($line = readline ARGV)) {
        foreach $_ ($line =~ /lorem1/gi) {
            ++$loremcn;
            if ($loremcn >= 2) {
                $line =~ s/lorem1//gi;
            }
            print "$loremcn\n";
            print $line;
            chomp $line;
        }
    }


}
continue {
    die "-p destination: $!\n" unless print $_;
}

所以你看到你的代码中有两个 while 循环：你不应该将命令行选项与程序文件混为一谈，因为结果可能不明显

这是我认为你想要的一种方法。它使用你的全局计数器 $loremcn 和一个 表达式 全局替换来替换 lorem1 在第一个实例之后什么都没有

#!/usr/bin/perl

use strict;
use warnings 'all';

@ARGV = 'file1.txt';

my $loremcn = 0;

while ( <> ) {

    s{(\blorem1\b[ \t]*)}{ $loremcn++ ? '' : $1 }ge;

    print;
}

输出

pierwsza linia  koniec
druga linia lorem1 koniec 
trzecia linia koniec 
czwarta linia koniec
piata liniakoniec
szosta linia koniec