如何使用Robot + Linux在json文件中以UTC（Zulu UTC）格式替换当前时间？

Question

我正在尝试使用 ROBOT 框架将 JSON 文件中的时间值替换为当前时间，但时间格式为 "YYYY-MM-DDTHH:MM:SS.SZ"，我无法弄清楚...

x.json

{

"abc": "123",

"xyz": [ "a1b2c3"],

"time": "2021-02-04T13:01:27.4Z"

}

我想用当前时间或 [当前时间 + 3-5 分钟] 更新它， 假设当前时间是 18:00 我需要 JSON 中的值是 18:05

更新的 x.json

{

"abc": "123",

"xyz": [ "a1b2c3"],

"time": "2021-02-04T18:05:00.0Z"

}

我尝试使用sed，但它无法更改为"YYYY-MM-DDTHH:MM:SS.SZ" 格式。 即使date -u 也不会以上述格式返回。

有没有办法使用 ROBOT + linux 命令来做到这一点？

Answer 1

Robot 有一个 DateTime 库，可以轻松将字符串转换为日期，并获取当前日期。一旦你有了一个日期对象，你就可以随心所欲地操作它。

以下示例将执行以下操作：

• 从 x.json 导入 json 数据
• 将其转换为 python 对象
• 获取当前日期
• 将新日期保存到 python 对象
• 将 python 对象转换回 json 字符串
• 将json字符串写入x.json

这不会保留原始数据的确切格式（即：不保留空白行），但 x.json 仍将是有效的 json，但时间已更改。

*** Settings ***
Library  DateTime
Library  OperatingSystem
Library  Collections

*** Test cases ***
Example 1
    # read the raw data
    ${json}=   Get file   x.json

    # convert the data to a python object
    ${object}=  Evaluate  json.loads($json)

    # Get the current date/time in UTC
    ${new_date}=  get current date  time_zone=utc

    # save the new data to the dictionary
    Set to dictionary  ${object}  time=${new_date}

    # convert the object back to json
    ${json}=  evaluate  json.dumps($object, indent=4)

    log to console  \n${json}

    # overwrite the original file with the new json
    create file  x.json  content=${json}