匹配多个文件中的多个模式

Question

我想在具有相同扩展名的多个文件中匹配/检查多个模式pattern1、pattern2...文件，它返回false。 示例：

file1.ext

this file has pattern1
with many other lines

file2.ext

this file has pattern2
with many other lines

在这种情况下，由于 pattern1 和 pattern2 都存在（尽管在不同的文件中），它应该返回 true。也就是说，所有模式都必须存在于文件中。

我们可以做到这一点的一种方法是使用 grep 在所有文件中单独搜索每个模式，并检查每个 grep 是否返回至少 1 个匹配项。
grep -R 'pattern1' --include="*.ext"
grep -R 'pattern2' --include="*.ext"
...
但这会很昂贵，因为可能需要搜索大量文件和多种模式。 另一种方法是grep 为所有带有| 的模式并解析输出以检查是否找到了所有模式。
grep -oR 'pattern1\|pattern2' --include="*.ext"

输出：

file2.ext:pattern2
file1.ext:pattern1

PS：在文件中搜索模式是我正在编写的 python 脚本的要求之一。

编辑：关于这里模式的含义的一些上下文。
模式是一个字符串。它可能包含特殊字符。 即使pattern 是一行中的子字符串，也应该发生匹配。更好的模式示例：

文件：

move-result-object v0
invoke-virtual {v0, v2}, Landroid/content/Intent;->hasExtra(Ljava/lang/String;)Z
move-result v3
const/4 v4, 0x0
if-nez v3, :cond_0

图案：

Landroid/content/Intent;->hasExtra

Answer 1

听起来可能是你想要的（未经测试）：

awk '
    BEGIN { OFS=":" }
    NR==FNR {
        tgts[$0]
        next
    }
    {
        for ( tgt in tgts ) {
            if ( index($0,tgt) ) {
                print FILENAME, tgt
                delete tgts[tgt]
                if ( length(tgts) == 0 ) {
                    allFound = 1
                    exit
                }
            }
        }
    }
    END {
        exit !allFound
    }
' targets *.ext

以上假设：

1. 您有一个支持 length(array) 的 awk 版本（大多数都支持）。
2. 您有一个名为 targets 的文件，其中列出了您要查找的所有“模式”，每一个都在自己的行中。
3. “返回真/假”是指“以成功/失败退出状态退出”。

Answer 2

使用 awk。但首先是模式文件：

$ cat patterns
pattern1
pattern2

然后是 awk：

awk '
NR==FNR {                     # process pattern file
    a[$0]                     # hash all patterns to a
    next
}
{                             # process the rest of the files
    for(i=1;i<=NF;i++)        # loop all strings
        if($i in a) {         # if string matches a string in pattern file
            print $i,FILENAME # print matched string and filename
            delete a[$i]      # remove it
        }
    for(j in a)               # continue while words strings left in a hash
        next
    exit ec=0                 # or exit once all are found
}
END {         
    if(ec=="")                # if we reach end without exiting
        exit 1                # not all strings were found
}' patterns file1 file2

“输出”：

$ echo $?  # true/false as exit code: 0=all found, 1=not all found
0           

编辑：在添加print $1,FILENAME（和它周围的{}s）之后，它现在还会打印匹配的字符串和第一次匹配的文件。