EARLIER 函数在 DAX 中不起作用 - 股票的 ATR

Question

我正在 PowerBI 中制作 ATR34 列，其中有一个表格，其中包含股票、日期、最高价、最低价、收盘价、PrevClose 和系列（包含股票、期货）。 我从 High Low Close 和 Prev Close 中计算了 ATR 列。我需要计算按 Stocks and Equity 过滤的 34 天 ATR 的 MA。

为此，我首先计算 Daynumber 过滤 Stocks 和 EQ；然后是 34 天并取平均值。 但是，当我在 DAX EARLIER 函数中使用下面提到的代码时，我无法计算它。

我是 POWERBI 的初学者。

DayNumber =
COUNTROWS (
    FILTER ('Table','Table'[Date] <= EARLIER ( 'Table'[Date] )),
    FILTER('Table'[Stock] = EARLIER ( 'Table'[Stock] )),
    FILTER('Table'[EQ] = EARLIER ( 'Table'[EQ] ))
)

Another Caulcated Measured Column : 

FirstDateOfRange34 =
CALCULATE (
    VALUES ( 'Table'[Date] ),
    FILTER ( 'Table','Table'[DayNumber] = EARLIER ( 'Table'[DayNumber] ) - 34),
    FILTER('Table'[Stock] = EARLIER ( 'Table'[Stock] )),
    FILTER('Table'[EQ] = EARLIER ( 'Table'[EQ] ))
)

Another Calculated Measured Column : 
ATR34 =
CALCULATE (
    AVERAGE ( 'Table'[ATR] ),
    FILTER ( 'Table','Table'[Date] >= EARLIER ( 'Table'[FirstDateOfRange34] ))
    FILTER ('Table','Table'[Date] <= EARLIER ( 'Table'[Date] ))
    FILTER('Table'[Stock] = EARLIER ( 'Table'[Stock] ))
    FILTER('Table'[EQ] = EARLIER ( 'Table'[EQ] ))
)

Answer 1

您的语法已关闭。 COUNTROWS 需要一个表参数，而不是三个参数，FILTER 需要一个表作为第一个参数，而不是列。

试试这个：

DayNumber =
COUNTROWS (
    FILTER (
        'Table',
        'Table'[Date] <= EARLIER ( 'Table'[Date] )
            && 'Table'[Stock] = EARLIER ( 'Table'[Stock] )
            && 'Table'[EQ]    = EARLIER ( 'Table'[EQ] )
    )

FirstDateOfRange34 =
CALCULATE (
    VALUES ( 'Table'[Date] ),
    FILTER (
        'Table',
        'Table'[DayNumber] = EARLIER ( 'Table'[DayNumber] ) - 34
            && 'Table'[Stock] = EARLIER ( 'Table'[Stock] )
            && 'Table'[EQ]    = EARLIER ( 'Table'[EQ] )
    )
)

ATR34 =
CALCULATE (
    AVERAGE ( 'Table'[ATR] ),
    FILTER (
        'Table',
        'Table'[Date] >= EARLIER ( 'Table'[FirstDateOfRange34] )
            && 'Table'[Date] <= EARLIER ( 'Table'[Date] )
            && 'Table'[Stock] = EARLIER ( 'Table'[Stock] )
            && 'Table'[EQ]    = EARLIER ( 'Table'[EQ] )
    )
)