如何使我的 sparql 使用正则表达式查询更快？答案

【问题标题】：How to make my sparql query with regex faster?如何使我的 sparql 使用正则表达式查询更快？
【发布时间】：2012-11-26 20:48:17
【问题描述】：

我已经为 dbpedia 构建了一个 sparql 查询，其中包含一个非常慢的正则表达式：

PREFIX rdf:<http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dbpedia-owl:<http://dbpedia.org/ontology/>

select ?label where {
    ?s rdfs:label ?label.
    ?s dbpedia-owl:thumbnail ?photo.
    ?s dbpedia-owl:abstract ?abstract.
    FILTER langMatches( lang(?label), "FR" ).
    FILTER langMatches( lang(?abstract), "FR" ).
    FILTER regex(?label, "^Jules V", "i").

}
LIMIT 10

您可以使用公共端点http://fr.dbpedia.org/sparql 进行尝试，但您必须等待几秒钟。

有没有办法让我在这方面获得更好的表现，即使最终质量不太好？

谢谢，塞缪尔

【问题讨论】：

您是否确定了缓慢的位，或者您只是猜测它可能是正则表达式？

标签： regex performance sparql dbpedia

【解决方案1】：

使用REGEX 的任何查询几乎肯定会很慢，除非您的查询仅限于数据集的足够小部分。处理REGEX 基本上需要商店对潜在结果进行线性扫描，检查每个结果是否与正则表达式匹配。

如果你有一个足够简单的正则表达式，你应该尝试以下两种方法之一：

解决方案 1 - 使用重量更轻的字符串函数

在您的情况下，您正在寻找以某个子字符串开头的字符串，因此使用 STRSTARTS 函数几乎肯定会更有效，因为它不需要完整的正则表达式。这当然假设您的 SPARQL 引擎符合最新的 SPARQL 1.1 草案规范。

解决方案 2 - 使用全文搜索

许多商店都包含全文搜索扩展程序，可以用来代替REGEX，并且通常会产生明显更好的性能，因为您访问的是全文索引而不是对潜在结果进行线性扫描。

对于 DBPedia，其背后的 Virtuoso 存储支持以下语法：

?label bif:contains "Jules"

请注意，Virtuoso 全文语法有些限制，因此您不能按原样使用Jules V，因为每个术语必须至少有 4 个字符（可能是 3 个）。但是您可以将其与进一步的FILTER 结合起来，以缩小您想要的结果，如下所示：

PREFIX rdf:<http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dbpedia-owl:<http://dbpedia.org/ontology/>

select ?label where {
    ?s rdfs:label ?label.
    ?s dbpedia-owl:thumbnail ?photo.
    ?s dbpedia-owl:abstract ?abstract.
    FILTER langMatches( lang(?label), "FR" ).
    FILTER langMatches( lang(?abstract), "FR" ).
    ?label bif:contains "Jules" .
    FILTER (CONTAINS(?label, "V"))

}
LIMIT 10

这个查询几乎立即运行

【讨论】：