使用 SPARQL 提取包含特定子字符串的三元组

Question

我想提取一个三元组，它的主题中包含“爱丽丝”这个词。我使用的查询是：

SELECT ?s ?p ?o  WHERE { ?s ?p ?o .FILTER regex(?s, \"alice\") .}

尽管有一个满足此约束的三元组，但这并没有给我任何结果。

另一方面，当我使用相同的查询来提取在其对象中包含单词 brillant 的三元组时。它只返回 2 个可能的匹配项中的一个。

使用的查询是：

SELECT ?s ?p ?o  WHERE { ?s ?p ?o .FILTER regex(?o, \"brillant\") .}

请让我知道我哪里出了问题以及这种行为的原因是什么。

Answer 1

我假设引号周围的转义只是复制和粘贴的残余。 regex 的第一个参数必须是文字，但文字不能是 RDF 中三元组的主题，因此您的数据不应该与此模式匹配。但是，您可能拥有的是 URI 包含字符串“alice”的主题，您可以使用 str 函数获取 URI 的字符串表示形式。例如，

SELECT ?s ?p ?o  WHERE { ?s ?p ?o .FILTER regex(str(?s), "alice") .}

为了说明，让我们使用两个值 <http://example.org> 和 "string containing example" 并像您在原始查询中所做的那样进行过滤：

select ?x where {
  values ?x { <http://example.org> "string containing example" }
  filter( regex(?x, "exam" ))
}

-------------------------------
| x                           |
===============================
| "string containing example" |
-------------------------------

我们只得到了"string containing example"，因为另一个值不是字符串，因此不是regex 的合适参数。但是，如果我们将调用添加到 str，那么正则表达式将考虑 URI 的字符串表示形式：

select ?x where {
  values ?x { <http://example.org> "string containing example" }
  filter( regex(str(?x), "exam" ))
}

-------------------------------
| x                           |
===============================
| <http://example.org>        |
| "string containing example" |
-------------------------------