两个资源之间的路径

Question

是否可以通过 SPARQL 查询计算连接两个实例的边数？我要找路。

Answer 1

您可以使用 SPARQL 的属性路径和聚合函数计算唯一路径中的边数。例如，对于这样的数据，它包含我们关心的两条路径（a 到 c 有两条边，d 到 g 三边）：

@prefix : <https://stackoverflow.com/questions/19587520/sparql-path-between-two-instance/> .

:a :p :b .  # a to c is a path of length 2
:b :p :c .  

:d :p :e .  # d to g is a path of length 3
:e :p :f .
:f :p :g . 

您可以使用如下查询。请注意，我使用了特定属性:p，而不是变量。这是必要的，因为 SPARQL 1.1 规范中的 9.1 Property Path Syntax 不允许在属性路径中使用变量。

prefix : <https://stackoverflow.com/questions/19587520/sparql-path-between-two-instance/>

select ?start ?end (count(?mid) as ?length)
where {
  values (?start ?end) { (:a :c) (:d :g) }
  ?start :p+ ?mid .
  ?mid :p* ?end .
}
group by ?start ?end 

得到这样的结果：

$ sparql --query query.rq --data data.n3
------------------------
| start | end | length |
========================
| :d    | :g  | 3      |
| :a    | :c  | 2      |
------------------------

有关此处发生的事情的更完整描述，请参见：

• Calculate length of path between nodes?（其实就是看树上的路径）
• this answer 到 Finding all steps in property path（请注意，接受的答案说你不能这样做，但链接的答案表明你实际上可以）；和
• Is it possible to get the position of an element in an RDF Collection in SPARQL? 接受的答案。

不过，基本的想法是，如果你有一条从?start 到?end 的路径，那么对于?mid 的一堆不同值，你还有一条从?start 到的路径?mid 和从?mid 到?end 的路径。您可以为?mid 选择的不同值的数量（如果您允许其中一个端点，而不允许另一个端点）正是路径的长度。