在 SPARQL 查询中加入语义端点

Question

我正在尝试提出一个同时使用 bibleontology 和 dbpedia 语义数据库的请求：

PREFIX bibleontology: <http://bibleontology.com/resource/>
PREFIX dbo: <http://dbpedia.org/ontology/>

SELECT ?art ?abstract WHERE { 
bibleontology:Ezra owl:sameAs ?art .
?art dbo:abstract ?abstract .
}

这种请求既不适用于 bibleontology SPARQL 端点，也不适用于 dbpedia SPARQL 端点。请求的各个部分在每个 SPARQL 端点上都可以正常工作。

这种方式可以加入数据库吗？

Answer 1

我是 bibleontology.com 的工程师

bibleontology.com 采用 SPARQL1.1

PREFIX bibleontology: <http://bibleontology.com/resource/>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
SELECT ?art ?abstract
WHERE {
SERVICE <http://bibleontology.com/sparql/> { bibleontology:Ezra owl:sameAs ?art . }
SERVICE <http://dbpedia.org/sparql> { ?art dbo:abstract ?abstract . } }

Answer 2

该查询在 dbpedia 或 bibleontology 上都不起作用，因为信息存储在两个不同的数据库中，当您运行 SPARQL 查询时，您基本上会选择其中一个。这意味着您必须从两个数据库下载数据并将它们放入本地三重存储，以便能够像您展示的那样运行 SPARQL 查询。另一种选择是使用为您执行此操作的库。

The Semantic Web Client Library 将遵循您在 SPARQL 查询中拥有的所有 URI，并从每个资源下载 RDF 数据，以便它可以加入您查询中出现的所有三元组模式并给出答案。

您可以通过一些小的更改来运行您的查询：

PREFIX bibleontology: <http://bibleontology.com/resource/>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dbpedia: <http://dbpedia.org/ontology/> 

SELECT * WHERE { 
bibleontology:Ezra owl:sameAs ?art .
?art dbpedia:abstract ?abstract .
FILTER langMatches( lang(?abstract), "EN" )
} 

改动说明：

1. 包括owl 和dbpedia 命名空间
2. ?art dbpedia:abstract ?abstract . 你需要匹配 dbpedia:abstract 谓词来获取摘要而不是 bibleontology:abstract 以便从 dbpedia 获取摘要
3. 我还添加了filter 以仅检索英文摘要，这当然是可选的。

下载“The Semantic Web Library”并将查询放入文件（即：query.sparql）后，您可以运行以下命令来测试您的查询：

./semwebquery -sparqlfile query.sparql -retrieveduris -maxsteps 5

语义 Web 客户端库文档中解释了所有命令参数。

你会得到以下输出：

| ?art                               | ?abstract
| <http://dbpedia.org/resource/Ezra> | "Ezra is a major .... "@en |

Successfully dereferenced URIs: 

http://www.w3.org/2002/07/owl
http://bibleontology.com/data/Ezra
http://dbpedia.org/data/Ezra.xml
http://dbpedia.org/data3/abstract.n3

为简单起见，我省略了来自 dbpedia 的长摘要。 “成功取消引用的 URI”列表是库检索的文档以回答您的查询。在该库的文档中，您将了解如何在 Java 中以编程方式运行查询。

Answer 3

所有其他答案都是正确的，因为您无法按原样进行查询，因为数据未组合在单个 SPARQL 端点中。如果其中一个端点支持 SPARQL 1.1 联合查询，那么您可以像这样使用 SERVICE 关键字：

PREFIX bibleontology: <http://bibleontology.com/resource/>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>

SELECT ?art ?abstract
WHERE 
{ 
  bibleontology:Ezra owl:sameAs ?art .
  SERVICE <http://dbpedia.org/sparql?default-graph-uri=http://dbpedia.org> { ?art dbo:abstract ?abstract . }
}

您将上述查询提交到 bibleontology SPARQL 端点，并假设它支持 SERVICE 关键字，它会将您的部分查询发送到 DBPedia SPARQL 端点。

即使您的 SPARQL 端点支持 SERVICE 关键字，那么您仍然依赖于两个数据集中的相关数据，即圣经本体需要有一个指向 DBPedia 资源的 owl:sameAs，以便 @ 987654328@子句其实什么都找。

或者

如果您的两个端点都不支持 SERVICE 关键字，那么您可以设置本地端点或使用支持 SERVICE 关键字的命令行工具（如果您有兴趣，我会挖掘一些链接）和然后发出以下命令：

PREFIX bibleontology: <http://bibleontology.com/resource/>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>

SELECT ?art ?abstract
WHERE 
{ 
  SERVICE <http://bibleontology.com/sparql> { bibleontology:Ezra owl:sameAs ?art . }
  SERVICE <http://dbpedia.org/sparql?default-graph-uri=http://dbpedia.org> { ?art dbo:abstract ?abstract . }
}

如果您的本地工具/端点支持SERVICE，那么它将能够将查询的相关部分发送到相关端点并在本地进行连接，并希望返回您所追求的结果