【问题标题】:Product of two columsn, added to the next row, and so forth两列的乘积,添加到下一行,依此类推
【发布时间】:2018-08-15 03:32:09
【问题描述】:

我正在尝试在多行文件中的每一行中生成产品,并将其添加到后续行等等。

所以我基本上会选择

awk '{print $1 "/t" ($2 * $3)' filename > temp

如何为第 1 列中的每个唯一 ID 循环?下面的示例数据。

样本数据

name1   14   10
name1   48   10
name2   23   98
name3   90   28
name4   83   6
name4   5    3
name3   15   7

【问题讨论】:

  • 感谢您为解决问题所付出的努力,请务必在您的帖子中添加预期的输出。
  • 抱歉没有说得更清楚。

标签: awk pipe multiple-columns


【解决方案1】:

如果我没看错,您需要在每行中将第 2 列和第 3 列相乘,然后将它们添加到相同的第 1 列值,如果是这种情况,那么下面的内容可能会对您有所帮助。

awk '{a[$1]=(a[$1]?a[$1]+($2 * $3):$2*$3)} END{for(i in a){print i,a[i]}}' Input_file

解决方案二:您可以使用sort 和awk,以防您需要按排序顺序输出。

sort -k1 Input_file |
awk '
prev!=$1 && prev{
  print prev,total
  total=prev=""
}
{
  total+=($2*$3)
  prev=$1
}
END{
  if(prev && total){
    print prev,total
  }
}'

解决方案 3:如果您需要与 Input_file 的第一个字段相同的输出顺序,那么以下可能会有所帮助。

awk '
!a[$1]++{
  b[++count]=$1
}
{
  c[$1]=(c[$1]?c[$1] + ($2*$3):($2*$3))
}
END{
  for(i=1;i<=count;i++){
    print b[i],c[b[i]]
  }
}'  Input_file

输出如下。

name1 620
name2 2254
name3 2625
name4 513

【讨论】:

  • @serious,无需道歉,我们都在这里学习,继续学习,继续在这个伟大的网站上分享知识。
猜你喜欢
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
相关资源
最近更新 更多