Excel VBA，多参数过滤器返回行ID

Question

我目前有一个算法可以处理我的 Excel 工作簿中第 24 页上的数据。我有 3 个整数 a、b 和 c，它们来自工作表 24 上的数据，我需要使用它们在工作表 14 上返回唯一的行 ID。A、B 和 C，每个代表它们对应的列（范围) 在表 14 IE 上：表 24 中的 Int a 在表 14 的 A 列中。Int b 在 b 列中，c 在 c 中。组合的数字将始终返回一个从 14 开始的单数行 ID，在这种情况下为整数行。我很难用 Filter、evaluate 和一堆其他 Excel 函数编写语句。有谁知道如何从在一张纸上执行的算法启动一个脚本，并使用它产生的 a、b、c 的三个搜索数字在第 14 页中提取一个行 ID？

row = Sheets("Physical Disk Details").Columns("A").Find(what:=a, LookIn:=xlValues, lookat:=xlWhole) * Sheets("Physical Disk Details").Columns("B").Find(what:=b, LookIn:=xlValues, lookat:=xlWhole) * Sheets("Physical Disk Details").Columns("C").Find(what:=c, LookIn:=xlValues, lookat:=xlWhole)

Answer 1

此函数将返回与为 a、b 和 c 提供的内容完全匹配的第一个行号。它演示了最简单的 Range 迭代和 If/Then 测试之一，这些测试构成了您将在 Excel VBA 中找到的大多数数据模式搜索子例程的基础。有一些方法可以简化此代码，但它演示了基本原理。

如果你阅读了这段代码的每一行并理解了它的全部作用，你就可以使用这些原则来完成大多数任务，甚至是与它模糊相似的任务。

Function GetRowNumberByABCMatch(a As Integer, b As Integer, c As Integer) As Integer
    Dim lastRowInDataSet As Integer
    Dim i As Integer

    'get last row containing data in column 1
    lastRowInDataSet = Sheets("Physical Disk Details").Cells(Rows.count, 1).End(xlUp).Row

    'i = current row number, start at row 1
    For i = 1 To lastRowInDataSet
        If Sheets("Physical Disk Details").Range("A" & i).Value = a _
                And Sheets("Physical Disk Details").Range("B" & i).Value = b _
                And Sheets("Physical Disk Details").Range("C" & i).Value = c Then
            'all fields match, return the current row number
            GetRowNumberByABCMatch = i
            'stop processing and return because we found a single match
            Exit Function
        End If
    Next i

    'didn't find a matching row, return -1
    GetRowNumberByABCMatch = -1
End Function