EBNF语法到ANTLR3？

Question

我有这个 Jass 脚本语言的 EBNF 语法。
需要做什么才能将其转换为与 ANTLR 3.5 一起使用？
此外，是否有任何工具可以帮助我这样做？

//----------------------------------------------------------------------
// Global Declarations
//----------------------------------------------------------------------
program  ::= file+
file     ::= newline? ( declr newline )* func*
declr    ::= typedef
           | globals
           | native_func
typedef  ::= 'type' id 'extends' ( 'handle' | id )
globals  ::= 'globals' newline global_var_list 'endglobals'
global_var_list
         ::= ( 'constant' type id '=' expr newline | var_declr newline )*
native_func
         ::= 'constant'? 'native' func_declr
func_declr
         ::= id 'takes' ( 'nothing' | param_list ) 'returns' ( type | 'nothing' )
param_list
         ::= type id ( ',' type id )*
func     ::= 'constant'? 'function' func_declr newline local_var_list statement_list 'endfunction' newline

//----------------------------------------------------------------------
// Local Declarations
//----------------------------------------------------------------------
local_var_list
         ::= ( 'local' var_declr newline )*
var_declr
         ::= type id ( '=' expr )?
           | type 'array' id
statement_list
         ::= ( statement newline )*
statement
         ::= set
           | call
           | ifthenelse
           | loop
           | exitwhen
           | return
           | debug
set      ::= 'set' id '=' expr
           | 'set' id '[' expr ']' '=' expr
call     ::= 'call' id '(' args? ')'
args     ::= expr ( ',' expr )*
ifthenelse
         ::= 'if' expr 'then' newline statement_list else_clause? 'endif'
else_clause
         ::= 'else' newline statement_list
           | 'elseif' expr 'then' newline statement_list else_clause?
loop     ::= 'loop' newline statement_list 'endloop'
exitwhen ::= 'exitwhen' expr
return   ::= 'return' expr?
debug    ::= 'debug' ( set | call | ifthenelse | loop )

//----------------------------------------------------------------------
// Expressions
//----------------------------------------------------------------------
expr     ::= binary_op
           | unary_op
           | func_call
           | array_ref
           | func_ref
           | id
           | const
           | parens
binary_op
         ::= expr ( [+-*/><] | '==' | '!=' | '>=' | '<=' | 'and' | 'or' ) expr
unary_op ::= ( '+' | '-' | 'not' ) expr
func_call
         ::= id '(' args? ')'
array_ref
         ::= id '[' expr ']'
func_ref ::= 'function' id
const    ::= int_const
           | real_const
           | bool_const
           | string_const
           | 'null'
int_const
         ::= decimal
           | octal
           | hex
           | fourcc
decimal  ::= [1-9] [0-9]*
octal    ::= '0' [0-7]*
hex      ::= '$' [0-9a-fA-F]+
           | '0' [xX] [0-9a-fA-F]+
fourcc   ::= '' ' .{4} ' ''
real_const
         ::= [0-9]+ '.' [0-9]*
           | '.' [0-9]+
bool_const
         ::= 'true'
           | 'false'
string_const
         ::= '"' .* '"'
parens   ::= '(' expr ')'

//----------------------------------------------------------------------
// Base RegEx
//----------------------------------------------------------------------
type     ::= id
           | 'code'
           | 'handle'
           | 'integer'
           | 'real'
           | 'boolean'
           | 'string'
id       ::= [a-zA-Z] ( [a-zA-Z0-9_]* [a-zA-Z0-9] )?
newline  ::= '\n'+

提前感谢您提供的任何建议！

Answer 1

免责声明：我实际上并没有使用 ANTLR，因此使用过的人可能会提供更详细的信息。

ANTLR 生成递归下降解析器，因此必须重构您的语法以消除左递归，例如在expr:

expr     ::= binary_op
...
binary_op
         ::= expr ( [+-*/><] | '==' | '!=' | '>=' | '<=' | 'and' | 'or' ) expr

在解析expr 时，解析器会尝试binary_op 作为一个选项，遇到另一个expr，然后尝试在不消耗任何输入的情况下递归解析它，您现在将拥有无限递归。

这通常通过重新制定语法来处理

expr     ::= binary_op
...
binary_op
         ::= term ( [+-] term )

term = factor ( [*/] factor)

factor = id
         | const
         | parens
         ...

等等。

不是一个简单的过程，但也不是不可能做到的。

Answer 2

您询问了任何建议，但奇怪的是您的问题特定于 Antlr 3.5。您有使用 Antlr 3.5 的要求吗？了解您将使用语法做什么会有所帮助：简单的语法验证还是完整的解释器？

如果您可以考虑使用 Antlr 4，那么您应该这样做。它比 Antlr 3 更好地处理左因子规则，并且由于您似乎只是在学习 Antlr，Antlr 4 IMO 将更容易上手。如果你真的需要 AST，那就用 Antlr 3

不幸的是，自动转换工具充其量只会给你一个糟糕的语法开发起点。

至于从哪里/如何开始，最好的建议是获取 Java 语法的副本（java.g 用于 Antlr 3.5 或 java.g4 用于 Antlr 4）作为一个工作示例——Jess 似乎足够类似于 java 语法应该让您清楚地了解如何进行。

Answer 3

语法描述语言真的很小。他们的语法只有十几个规则。

您可以做的（我已经做过的事情）是使用 ANTLR 为 EBNF 表示法编写语法，并使用它来将您拥有的内容转换为 ANTLR 语法。

应该是一天的工作，最多两天。