如何在 VB.net 中将 datagridview 中的多行插入 SQL 数据库？

Question

我创建了一个名为form1.vb的表单。
我有 4 个名为 supid、supname、supmobile、suploc 的文本框。
我有一个名为 datagridview1 的 DataGridView。
我在 DataGridView 中传输这 4 个 TextBoxes 数据，但是当我尝试在 SQL 数据库中发送 DataGridView 行时，它只发送 1 行。

单击插入按钮时，我希望在 SQL Server 中一次插入多行。
有很多关于C语言的教程，但是没有关于VB.Net的教程。
请在VB.Net 中帮助如何做到这一点。

我的代码：

Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click

    If TextBox2.Text = "" Or TextBox3.Text = "" Or TextBox4.Text = "" Then
        MessageBox.Show("PLEASE FILL ALL FIELDS")
    Else
        connection.Open()
        Dim thequery As String = "select*from supplierdata where supmobile = @supmobile"
        Dim cmd1 As SqlCommand = New SqlCommand(thequery, connection)
        cmd1.Parameters.AddWithValue("@supmobile", TextBox3.Text)

        Dim reader As SqlDataReader = cmd1.ExecuteReader()

        If reader.HasRows Then
            MessageBox.Show("MOBILE NO IS ALREADY REGISTERED")
        Else
            reader.Close()
            command = New SqlCommand("INSERT INTO supplierdata VALUES (@supid,@supname,@supmobile,@suploc)", connection)
            Dim i As Integer = 0
            For Each row As DataGridViewRow In DataGridView1.Rows
                command.Parameters.Add("supid", SqlDbType.Int).Value = DataGridView1.Rows(i).Cells(0).value
                command.Parameters.Add("supname", SqlDbType.NChar).Value = DataGridView1.Rows(i).Cells(1).Value
                command.Parameters.Add("supmobile", SqlDbType.NChar).Value = DataGridView1.Rows(i).Cells(2).Value
                command.Parameters.Add("suploc", SqlDbType.NChar).Value = DataGridView1.Rows(i).Cells(3).Value

                i = command.ExecuteNonQuery()
            Next

            MessageBox.Show("CUSTOMER REGISTERED SUCCESFULLY")
            connection.Close()
            command.Dispose()
        End If
    End If
End Sub

Answer 1

1. 在您的第一个 If 语句中使用 OrElse 而不是 Or。一旦检测到 True，这将停止评估。
2. 保持本地连接。它们应在最后一刻打开并尽快关闭和处置。一个Using...End Using 块会处理这个问题。
3. 如果您只需要计数，则只要求计数。不要检索您不使用的数据。不需要DataReader。只需使用ExecuteScalar。
4. 使用参数做得很好！
5. 在添加参数时，您在 Sql 查询中使用的参数名称必须与您的名称匹配。 （对于只关心参数添加顺序的 Access 而言，情况并非如此。）
6. 现在是真正的问题Dim i As Integer = 0 然后在 For Each 循环中使用DataGridView1.Rows(i).Cells(0).Value。行始终是第一行，并且它在循环中永远不会改变。这就是为什么“它只发送 1 行”
7. 您不想在For Each 循环中不断添加参数。
8. 还有一件事 - 如果 subid 是自动增量列，则不要为该列发送任何数据。

未经测试的代码。我没有你的表格或数据库。

Private Sub OPCode2()
    If TextBox2.Text = "" OrElse TextBox3.Text = "" OrElse TextBox4.Text = "" Then
        MessageBox.Show("PLEASE FILL ALL FIELDS")
        Return
    End If
    Dim count As Integer
    Try
        Using cn As New SqlConnection("Your connection string")
            Dim thequery As String = "select Count(*) from supplierdata where supmobile = @supmobile;"
            Using cmd1 As SqlCommand = New SqlCommand(thequery, cn)
                cmd1.Parameters.AddWithValue("@supmobile", TextBox3.Text)
                cn.Open()
                count = CInt(cmd1.ExecuteScalar())
            End Using
        End Using
    Catch ex As Exception 'You probably want to catch more specific exceptions
        'and handle them separately
        MessageBox.Show(ex.Message)
    End Try
    If count > 0 Then
        MessageBox.Show("MOBILE NO IS ALREADY REGISTERED")
        Return
    End If
    Try
        Using cn As New SqlConnection("Your connection string")
            Using cmd2 As New SqlCommand("INSERT INTO supplierdata (supid,supname,supmobile,suploc)VALUES (@supid,@supname,@supmobile,@suploc)", cn)
                cmd2.Parameters.Add("@supid", SqlDbType.Int)
                cmd2.Parameters.Add("@supname", SqlDbType.NChar)
                cmd2.Parameters.Add("@supmobile", SqlDbType.NChar)
                cmd2.Parameters.Add("@suploc", SqlDbType.NChar)
                cn.Open()
                For Each row As DataGridViewRow In DataGridView1.Rows
                    With cmd2
                        .Parameters("@supid").Value = row.Cells(0).Value
                        .Parameters("@supname").Value = row.Cells(1).Value
                        .Parameters("@supmobile").Value = row.Cells(2).Value
                        .Parameters("@suploc").Value = row.Cells(3).Value
                    End With
                    cmd2.ExecuteNonQuery()
                Next
            End Using 'You probably want to catch more specific exceptions
            'and handle them separately
        End Using
    Catch ex As Exception 'You probably want to catch more specific exceptions
        'and handle them separately
        MessageBox.Show(ex.Message)
    End Try
    MessageBox.Show("CUSTOMER REGISTERED SUCCESFULLY")
End Sub

编辑 如果supid 是自动增量列，则将其从参数中删除。 将插入查询更改为 "INSERT INTO supplierdata (supname,supmobile,suploc)VALUES (@supname,@supmobile,@suploc)" 然后你需要删除这些行 cmd2.Parameters.Add("@supid", SqlDbType.Int) 和 .Parameters("@supid").Value = row.Cells(0).Value 仅当 supid 为自动递增（标识列）时才执行此操作