SQL Server：事务和更新语句出错

Question

我试图在 Else 语句中连续更新两个表。

因此，我将我的 Update 语句包装在一个事务中，我认为这是正确的方法，但在尝试执行此操作时出现以下错误。所有变量都在存储过程的开头声明。

我在这里错过了什么或做错了什么？

Msg 156, Level 15, State 1, Line 1
Incorrect syntax near the keyword 'ELSE'.
Msg 137, Level 15, State 2, Line 4
Must declare the scalar variable "@parentID".
Msg 137, Level 15, State 2, Line 11
Must declare the scalar variable "@lastUpdate".

我的 SQL（更新：发布完整查询）：

ALTER PROCEDURE [dbo].[MOC_UpdateNav]
    @itemID int,
    @parentID int,
    @itemName nvarchar(100),
    @linkRef nvarchar(2000),
    @sortID int,
    @lastUpdate nvarchar(50),
    @modBy varchar(50)
AS
BEGIN
    SET NOCOUNT ON; 

    IF NOT EXISTS 
    (
            SELECT  * 
            FROM    MOC_Links
            WHERE   itemID = @itemID
    )
            INSERT INTO MOC_Links
            (
                    parentID,
                    itemName,
                    linkRef,
                    sortID
            )
            SELECT  @parentID,
                    @itemName,
                    @linkRef,
                    @sortID

            INSERT INTO MOC_Log
            (
                    lastUpdate,
                    modTime,
                    modBy
            )
            SELECT  @lastUpdate,
                    GETDATE(),
                    @modBy
    ELSE
            BEGIN TRANSACTION
                UPDATE  MOC_Links
                SET     parentID = @parentID,
                        itemName = @itemName,
                        linkRef = @linkRef,
                        sortID = @sortID
                WHERE   itemID = @itemID

                UPDATE  MOC_Log
                SET     lastUpdate = @lastUpdate,
                        modTime = GETDATE(),
                        modBy = @modBy
                WHERE   itemID = @itemID
            COMMIT
END

Answer 1

确保您已声明 @parentID 和 @lastUpdate 变量，并在 ELSE BLOCK 内将整个事务包装在 BEGIN..END 块内。其余的对我来说都很好。

ALTER PROCEDURE [dbo].[MOC_UpdateNav]
    @itemID int,
    @parentID int,
    @itemName nvarchar(100),
    @linkRef nvarchar(2000),
    @sortID int,
    @lastUpdate nvarchar(50),
    @modBy varchar(50)
AS
BEGIN
    SET NOCOUNT ON; 

    BEGIN TRANSACTION;

    IF NOT EXISTS(SELECT 1 FROM MOC_Links WHERE itemID = @itemID)
      BEGIN  --<-- This block here

            INSERT INTO MOC_Links(parentID, itemName, linkRef, sortID)
            VALUES  (@parentID,@itemName,@linkRef,@sortID)

            INSERT INTO MOC_Log (lastUpdate,modTime,modBy)
            VALUES  (@lastUpdate,GETDATE(),@modBy)
     END
    ELSE
       BEGIN  --<-- This another block here

                UPDATE  MOC_Links
                SET      parentID = @parentID
                        ,itemName = @itemName
                        ,linkRef = @linkRef
                        ,sortID = @sortID
                WHERE   itemID = @itemID

                UPDATE  MOC_Log
                SET     lastUpdate = @lastUpdate
                        ,modTime = GETDATE()
                        ,modBy = @modBy
                WHERE   itemID = @itemID

      END

   COMMIT TRANSACTION;  
END

注意

不知道整个语句是什么样的，但是这个 TRANSACTION 包装器对整个 IF..ELSE 语句更有意义。你不觉得吗？