TSQL - 在事务语句中创建存储过程

Question

我有一个设置为投入生产的 sql 脚本。我已经将各种项目包装成单独的交易。在每个事务中，我们都创建了存储过程。我收到错误消息

消息 156，级别 15，状态 1，第 4 行 关键字“procedure”附近的语法不正确。

我创建了这个示例脚本来说明

Begin Try
Begin Transaction 
    -- do a bunch of add/alter tables here
    -- do a bunch of data manipulation/population here

    -- create a stored proc
  create procedure dbo.test
  as
  begin
    select * from some_table
  end
Commit  
End Try
Begin Catch
    Rollback  
    Declare @Msg nvarchar(max)
    Select @Msg=Error_Message();
    RaisError('Error Occured: %s', 20, 101,@Msg) With Log;
End Catch

该错误似乎暗示我无法在事务中创建存储过程，但我没有找到任何其他说明的文档（也许谷歌今天不友好）。

Answer 1

尝试在EXEC('...') 中执行create procedure，如下所示：

Begin Try
Begin Transaction 
    -- do a bunch of add/alter tables here
    -- do a bunch of data manipulation/population here

    -- create a stored proc
  EXEC ('create procedure dbo.test
  as
  begin
    select * from some_table
  end')
Commit  
End Try
Begin Catch
    Rollback  
    Declare @Msg nvarchar(max)
    Select @Msg=Error_Message();
    RaisError('Error Occured: %s', 20, 101,@Msg) With Log;
End Catch

GO

Answer 2

您不能以这种方式编写脚本，因为有许多语句必须在它们自己的批处理中运行。相反，我建议做一些类似于 Red-Gate 的 SQL 比较如何构建其脚本的事情：

Set Xact_Abort On
GO
Begin Transaction 
GO
If object_id('tempdb..#tmpErrors') is not null
    Drop Table #tmpErrors
GO
Create Table #tmpErrors( [Error] int not null )
GO
Create Procedure dbo.Test
As
Begin
    --....
End
GO
If @@Error <> 0 AND @@TranCount >0 Rollback Transaction
GO
IF @@TranCount = 0 Begin Insert #tmpErrors (Error) Select 1 Begin Transaction End
GO

-- more statements

GO
If @@Error <> 0 AND @@TranCount >0 Rollback Transaction
GO
IF @@TranCount = 0 Begin Insert #tmpErrors (Error) Select 1 Begin Transaction End
GO

--.....

IF NOT EXISTS(SELECT * FROM #tmpErrors)
    BEGIN
        PRINT 'The database update succeeded'
        IF @@TRANCOUNT > 0 COMMIT TRANSACTION
    END
ELSE 
    BEGIN
        PRINT 'The database update failed'
        IF @@TRANCOUNT > 0 ROLLBACK TRANSACTION
    END
GO

DROP TABLE #tmpErrors
GO

Answer 3

KM 提出的解决方案存在各种问题：

• 如果您在 EXEC() 调用中的内容在语义上不正确（例如，您在存储过程中的 FROM 中放置了一个不存在的表），则该错误不会冒泡并且事务没有回滚。

• 如果您在 EXEC() 调用中的内容在语法上不正确（例如，您将 SELECTT 而不是 SELECT 放入存储过程中），则事务似乎已回滚，但会出现一个完全神秘的错误：

  A transport-level error has occurred when receiving results from the server. (provider: TCP Provider, error: 0 - The specified network name is no longer available.)
  

所以我仍然不知道如何在事务中创建一个过程，但仍然让事务和 try-catch 有用。

Answer 4

我似乎记得您不能在事务中执行诸如创建、修改或删除数据库架构对象（包括存储过程）之类的操作（因为此类结构更改不是事务性的：您无法通过数据更改回滚它们）。