Tableadapter.Fill 不适用于手动查询源

Question

我有一个 Windows 窗体应用程序，其 DataGridView 由 TableAdapter 填充。我正在使用Fill 方法在循环的Async sub 中更新UI 的数据，就像这样。

Private Async Sub updateUI()
    Dim sw As New Stopwatch
    While True
        Await Task.Delay(3000)
        sw.Restart()
        myTableAdapter.Fill(getDataWithMySQL())
        'myTableAdapter.Fill(myDataSet.myTable)
        logger.Debug(sw.ElapsedMilliseconds)
    End While
End Sub

getDataWithMySQL函数如下：

Private Function getDataWithMySQL() As myDataSet.myDataTable
    Dim connStr As String = My.Settings.myConnectionString
    Dim sql As String = "SELECT ... LEFT JOIN ..."
    Dim dt As New myDataSet.myDataTable
    Using conn As New MySqlConnection(connStr)
        Using cmd As New MySqlCommand()
            With cmd
                .CommandText = sql
                .Connection = conn
            End With
            Try
                conn.Open()
                Dim sqladapter As New MySqlDataAdapter(cmd)
                sqladapter.Fill(dt)

            Catch ex As MySqlException
                MsgBox(ex.Message)
            End Try
        End Using
    End Using
    Return dt
End Function

myTableAdapter.Fill(myDataSet.myTable) 工作正常，但表现不佳，而 myTableAdapter.Fill(getDataWithMySQL()) 表现更好，正如我尚未回答的问题 here 中所报告的那样。

由于某种原因，myTableAdapter.Fill(getDataWithMySQL()) 不再起作用。它不会引发错误并且dt 填充了正确的数据，但DataGridView 没有更新。它以前工作过，我认为我没有改变任何会影响这一点的东西。任何想法为什么DataGridView 没有更新？

Answer 1

我相信您的问题源于您在方法调用中创建一个新的数据表并返回该数据表。您已经获得了所需的 DataSet.DataTable 的引用，只需使用该 DataTable 调用 Fill。

您的问题是您正在填充的数据表与您的网格正在使用的数据集没有关联。

Answer 2

这很可能是因为.Fill 命令在使用ByRef 时需要一个数据表。我认为发生的事情是您正在使用 getDataWithMySQL() 返回一个 DataTable，但随后您正在使用该 DataTable 并使用适配器的 .Fill 方法重新填充它，并且您使用 getDataWithMySQL() 方法返回的 DataTable 进入 lala 土地再也见不到了。

在这里做一些假设，但尝试一下：

Private Async Sub updateUI()
    Dim sw As New Stopwatch
    While True
        Await Task.Delay(3000)
        sw.Restart()
        Dim dt as myDataSet.myDataTable = getDataWithMySQL("SELECT ... LEFT JOIN ...")
        UpdateDGV(dt)
        'myTableAdapter.Fill(myDataSet.myTable)
        logger.Debug(sw.ElapsedMilliseconds)
    End While
End Sub

' You need to change `DataGridView` here to be the actual datagridview control on the form
Private Sub UpdateDGV(newSource as myDataSet.myDataTable)
    DataGridView.SuspendLayout()
    DataGridView.DataSource = Nothing
    DataGridView.DataSource = newSource 
    DataDridView.ResumeLayout()
End Sub

' Make the function easier to reuse by passing in the SQL command
Private Function getDataWithMySQL(sqlCmd as string) As myDataSet.myDataTable
    Dim connStr As String = My.Settings.myConnectionString
    Dim dt As New myDataSet.myDataTable
    Using conn As New MySqlConnection(connStr)
        Using cmd As New MySqlCommand()
            With cmd
                .CommandText = sqlCmd
                .Connection = conn
            End With
            Try
                conn.Open()
                Dim sqladapter As New MySqlDataAdapter(cmd)
                sqladapter.Fill(dt)

            Catch ex As MySqlException
                MsgBox(ex.Message)
            End Try
        End Using
    End Using
    Return dt
End Function