如何让我的 TCP 侦听器服务正确终止？

Question

我正在编写一个启动 TCP 侦听器的 Windows 服务。核心代码运行良好，但我在 Windows 服务的机制方面遇到了一些问题。

现在，当我的服务启动时，它会创建一个线程并在该线程中启动 TCP 侦听器。然后，当服务停止时，它会终止该线程：

Public Class txnSocketService
    Inherits System.ServiceProcess.ServiceBase

    Private listenerThread As Thread


    Public Sub New()
        Me.ServiceName = "txnSocketService"
        Me.CanStop = True
        Me.CanPauseAndContinue = True
        Me.AutoLog = True
    End Sub

    Shared Sub Main()
        System.ServiceProcess.ServiceBase.Run(New txnSocketService)
    End Sub

    Protected Overrides Sub OnStart(ByVal args() As String)
        listenerThread = New Thread(AddressOf pmtListener.Main)
        listenerThread.IsBackground = True
        listenerThread.Start()
    End Sub

    Protected Overrides Sub OnStop()
        listenerThread.Abort()
    End Sub

    Private Sub InitializeComponent()
        '
        'txnSocketService
        '
        Me.ServiceName = "txnSocketService"

    End Sub
End Class

启动工作正常。但是，如果我停止服务，服务进程不会终止。我做错了什么？

[顺便说一下，如果这很重要，我目前正在 VS2010 Beta 2 上执行此操作。]

Answer 1

您应该实现一些shutdown() 方法来优雅地关闭套接字，而不是使用Thread.Abort() 来终止线程。

例如

Public Class pmtListener
  Protected shutingdown As Boolean = False
  ' [...] '
  Public Sub Shutdown()
    shutingdown = True
    socketListen.Close()
  End Sub
  Sub Main()
    Dim socketAccepted As Socket
    shutingdown = False
    socketListen.Listen(3)
    While Not shutingdown
      Try
        socketAccepted = socketListen.Accept()
        ' do something with socketAccepted '
        socketAccepted.Close()
        socketAccepted = Nothing
      Catch ex As SocketException
        If shutingdown Then
          ' ignoring it '
        End If
      End Try

    End While
  End Sub

当 Shutdown() 调用 socketListen.Close() 并且工作线程当前正在等待新连接时，将引发 SocketExcpetion。我们只是忽略了这一点。
在您的 OnStop() 方法中，您首先通过调用 myListener.Shutdown() 让 pmtListener 实例有机会正常关闭（然后设置关闭标志并关闭套接字），然后等待（最多）某个时间跨度（例如一秒）。如果线程还活着，请尝试终止它。

Public Class txnSocketService
  Inherits System.ServiceProcess.ServiceBase

  Protected myListener as pmtListern
  Protected listenerThread As Thread

  ' [...] '
  Protected Overrides Sub OnStart(ByVal args() As String)
    myListener = new pmtListener
    listenerThread = New Thread(AddressOf myListener.Main)
    listenerThread.IsBackground = True
    listenerThread.Start()
  End Sub

  Protected Overrides Sub OnStop()
    myListener.Shutdown()
    listenerThread.Join(1000) ' give it a second '
    If listenerThread.IsAlive Then
      listenerThread.Abort()
    End If
  End Sub