从 Prolog 到 Haskell 的思考——生成真值组合列表

Question

我知道一点 Prolog，并且刚刚开始在 Haskell 中进行一些自学。我一直在通过99 Problems for Haskell 工作，一路上学到了很多东西，并且非常喜欢 Haskell。有时我试图通过在 Prolog 中编写一些代码来阐明我对问题空间的理解，然后思考该解决方案如何与 Haskell 中的函数式方法相关联。今晚，在处理有关逻辑的问题（问题 47 和 48）时，我分心了，试图完成一个简单的任务，即建立一个包含 n 个值的所有真值组合列表的列表。我想要一个函数tValues :: Int -> [[Bool]]。这个问题可以在 Prolog 中以非常直接和声明式的方式解决，例如：

combinations_of_n_truth_values(N, AllValues) :-
    findall(Values, n_truth_values(N, Values), AllValues).

n_truth_values(N, TruthValues) :-
    length(TruthValues, N),
    maplist(truth_value, TruthValues).

truth_value(true).
truth_value(false).

使用时，变量AllValues 将与所需的真值列表列表统一。我想知道有经验的 Haskell 程序员将如何解决同样的问题。我希望有一个同样直接和声明式的解决方案，但我似乎无法让我的 Haskell 大脑以正确的方式运作。

我已经使用列表推导来摆弄一些半模拟，例如：

tValues:: Int -> [[Bool]]
tValues 0 = []
tValues n = [v:vs | v  <- tValue
                  , vs <- tValues (n-1) ] 

tValue :: [Bool]
tValue = [True, False]

但tValues 只返回[]。我想我只需要一些人与人之间的接触来帮助我清醒地摇头，也许能让我有更深入的洞察力。

非常感谢。

Answer 1

在伪代码中，您的列表理解

[v:vs | v  <- tValue
      , vs <- tValues (n-1) ] 

等于

for any combination of two elements in `tValue`  and `tValues (n-1)`
    cons the first onto the latter

但是，tValues 没有以任何元素开头，它是一个空列表。让我们模拟一下n = 1：

tValues 1 = [v:vs | v  <- tValue
                  , vs <- tValues 0 ] 
          = [v:vs | v  <- [True, False]
                  , vs <- [] ] 
            -- since there is no vs
          = []

这会在整个递归中传播。解决方案非常简单：将基本情况更改为包含一个空组合：

tValues 0 = [[]] -- or: return []

现在模拟结果：

tValues 1 = [v:vs | v  <- tValue
                  , vs <- tValues 0 ] 
          = [v:vs | v  <- [True, False]
                  , vs <- [[]]] 
            -- vs is []
          = [True:[],False:[]]
          = [[True],[False]]

这正是我们想要的。

Answer 2

使用列表单子，

g n = mapM (\_-> [True, False]) [1..n]

关于您的函数的基本情况。由于该函数返回一个包含所有长度为n的真值列表的列表，因此对于n=0，它应该返回一个包含所有长度为0的真值列表，即包含一个空列表的列表。

Answer 3

truths :: [[Bool]]
truths = [True] : [False] : concatMap (\bs -> [True:bs, False:bs]) truths

truthValues :: Int -> [[Bool]]
truthValues n = dropWhile ((< n) . length) . takeWhile ((<= n) . length) $ truths

truths 是所有真值组合的无限列表，因为长度单调增加，我们可以只取列表的前面部分，而长度小于或等于我们正在寻找的集合，然后丢弃长度较短的前面。

你只得到空列表的原因是最终tValues (n-1) 评估为tValues 0，这当然是空列表。尝试从列表推导中的空列表中进行绘制会导致迭代失败。这会向上传播理解链。将基本情况更改为tValues 1 = [[True], [False]] 即可。

Answer 4

本身不是一个完整的答案，但如果您感兴趣，请使用 list monad：

truthValues ∷ Int → [[Bool]]
truthValues 0 = return []
truthValues n = truthValues (n - 1) >>= (\l → [True:l, False:l])

或

truthValues n = foldM (\l _ -> [True:l, False:l]) [] [1..n]

或

truthValues = flip replicateM [True, False]

另请参阅 Will Ness 的回答和随附的 cmets :)