StackOverflowException 在 VB.NET 中未处理

Question

我想使用以下代码将行从DataGridViewX1 移动到另一个表单的DataGridView：

按钮点击事件：

Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
    frmEncodeDatabase.EncodingCompleteDataGridView.DataSource = DataGridViewX1.Rows
    frmEncodeDatabase.Show()
End Sub

另一个表单的DataGridView 的RowsAdd 事件：

EncodingCompleteDataGridView.Rows.Add(frmEncode.DataGridViewX1.Rows)

现在上面的代码是我遇到问题的地方：StackOverflowException。 （错误描述如下图）

http://postimg.org/image/4d91ex49j/

Answer 1

这是一个通用示例，可​​帮助您朝着正确的方向前进。

这个例子：

• 演示如何将未数据绑定的 datagridview 中的行合并到数据绑定的 datagridview 中
• 假设两个 datagridview 的列数和顺序相同。
• 假设数据绑定的 gridview 绑定到数据表。

我意识到您的真实示例在单独的表单上具有数据网格视图，但对于此示例，代码更容易在一个表单上遵循。

要对此进行测试，请执行以下操作：

1）新建一个表单（Form1），添加2个datagridview（DataGridView1和DataGridView2）和一个按钮（Button1）

2) 将 Form1 上的代码替换为：

Public Class Form1
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        ' Manually add columns to the first datagridview which will not be data bound

        Me.DataGridView1.Columns.Add("Column1", "Column1")
        Me.DataGridView1.Columns.Add("Column2", "Column2")
        Me.DataGridView1.Columns.Add("Column3", "Column3")

        ' Poulate both datagridviews

        PopulateDataGrid1Manually()
        PopulateDataGrid2DataBound()
    End Sub

    Private Sub PopulateDataGrid1Manually()
        ' This datagridview has data added manually without being databound

        Dim sRow(Me.DataGridView1.ColumnCount - 1) As String

        For r As Int32 = 1 To 3 ' Adding 3 rows of test data
            For c As Int32 = 0 To Me.DataGridView1.ColumnCount - 1
                sRow(c) = "data" & r.ToString
            Next

            Me.DataGridView1.Rows.Add(sRow)
        Next
    End Sub

    Private Sub PopulateDataGrid2DataBound()
        ' This datagridview is databound to a datatable

        Dim dt As New DataTable

        dt.Columns.Add("Column1", GetType(String))
        dt.Columns.Add("Column2", GetType(String))
        dt.Columns.Add("Column3", GetType(String))

        Dim dr As DataRow

        For i As Int32 = 1 To 3 ' Adding 3 rows of test data
            dr = dt.NewRow
            dr("Column1") = "new" & i.ToString
            dr("Column2") = "new" & i.ToString
            dr("Column3") = "new" & i.ToString
            dt.Rows.Add(dr)
        Next

        Me.DataGridView2.DataSource = dt    ' Databind
    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ' Copy rows from the first datagridview to the second datagridview that is data bound
        ' First copy the second datagridviews datasource into a new data table

        Dim dt As DataTable = CType(Me.DataGridView2.DataSource, DataTable).Copy
        Dim dr As DataRow

        ' Loop through all rows of the first datagridview and copy them into the data table

        For r As Int32 = 0 To Me.DataGridView1.Rows.Count - 1
            If Me.DataGridView1.Rows(r).IsNewRow = False Then   ' Do not copy the new row
                dr = dt.NewRow

                ' Loop through all cells of the first datagridview and populate the data row

                For c As Int32 = 0 To Me.DataGridView1.ColumnCount - 1
                    dr(c) = Me.DataGridView1.Rows(r).Cells(c).Value
                Next

                dt.Rows.Add(dr) ' Add the data row to the data table
            End If
        Next

        Me.DataGridView2.DataSource = dt    ' Rebind the second datagridview with the new table which has all the rows from both datagridviews
    End Sub
End Class

Answer 2

Dim dt As DataTable = CType(DataGridView1.DataSource, DataTable) 
DataGridView2.DataSource = dt.Copy() 

它可以让我将内容从 dgv1 复制到 dgv2。