将 freetype 与 cmake 链接

Question

在使用extern C 库构建C++11 项目时，我无法在Linux 下使用cmake 链接freetype 2。

使用 cmake 和 freetype 2 我基本上有 2 个选项：

• 使用实用程序freetype-config 就像freetype-config --libs
• 使用FindFreetype cmake module

现在我正在尝试实现第二个选项，但我对cmake 不是很熟练，也不了解它的逻辑。

我的问题是链接阶段，我不知道如何正确地做到这一点，而且这个模块并不像 freetype-config --libs 的结果那样完整，它确实包括我需要的所有库和标志，而不仅仅是路径一个文件；所以我假设我必须为zlib 和libpng 做同样的事情。

CMakeLists.txt

cmake_minimum_required (VERSION 2.6)
project (FreetypeTutorials1)

include(FindFreetype)
include_directories(${FREETYPE_INCLUDE_DIRS})

SET(CMAKE_CXX_FLAGS "-O2 -std=c++11")

SET(CMAKE_EXE_LINKER_FLAGS "-v -lfreetype")

add_executable( demo "${CMAKE_CURRENT_SOURCE_DIR}/src/main.cpp")

./src/main.cpp（只是一些随机代码，所以我有一些东西可以提供给编译器）

extern "C" {
#include <ft2build.h>
#include FT_FREETYPE_H
}
#include <iostream>
int main()
{
  FT_Library library;
  auto error = FT_Init_FreeType(&library);
  if (error)
  {
    std::cout << "An error !\n";
  }
}

Answer 1

要加载像FindFreetype.cmake 这样的模块，您需要在cmake 中使用find_package-命令来使用它。第一个参数是包名。其对应文件名的“查找”由cmake自动添加。

虽然include 可能与find_package 一起使用，但您可以添加一些标志。比如下图REQUIRED，在找不到freetype的时候让cmake失败。

另外与 cmake 的链接应使用命令target_link_libraries 完成。

这就是我给你写 CMakeLists.txt 的方式：

cmake_minimum_required (VERSION 2.6)
project (FreetypeTutorials1)

find_package(Freetype REQUIRED)

SET(CMAKE_CXX_FLAGS "-O2 -std=c++11")

SET(CMAKE_EXE_LINKER_FLAGS "-v")

add_executable( demo src/main.cpp) # CMAKE_CURRENT_SOURCE_DIR is implicit here
target_link_libraries(demo ${FREETYPE_LIBRARIES})
target_include_directories(demo PRIVATE ${FREETYPE_INCLUDE_DIRS})

target_link_libraries 独立于平台，而CMAKE_EXE_LINKER_FLAGS 中的'-lfreetype 则不是。

CMakeLists.txt 将适用于其他提供 freetype 的平台。

（2019 年编辑：使用 target_include_directories() 而不是 include_directories()