XSLT 使用属性选择不同的值

Question

我正在尝试使用 XSLT 将列表转换为不同的值列表。

输入：

<object name="obj1"/>
<object name="obj2"/>
<object name="obj1"/>

期望的输出：

<object>obj1</object>
<object>obj2</object>

有人知道如何在 XSLT 1.0 或 2.0 中完成它吗？

谢谢

Answer 1

使用 XSLT 2.0 和

<xsl:for-each select="distinct-values(//object/@name)">
  <object><xsl:value-of select="."/></object>
</xsl:for-each>

或

<xsl:for-each-group select="//object" group-by="@name">
  <object><xsl:value-of select="current-grouping-key()"/></object>
</xsl:for-each-group>

Answer 2

对于 XSLT 1.0

objects.xml：

<?xml version="1.0" encoding="UTF-8"?>
<?xml-stylesheet type="text/xsl" href="objects.xsl"?>
<objects>
  <object id="id1" name="obj1"/>
  <object id="id2" name="obj2"/>
  <object id="id3" name="obj1"/>
</objects>

objects.xsl：

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:key name="index1" match="*" use="@name" />

    <xsl:template match="/">
        <objects>
        <xsl:for-each select="//*[generate-id() = generate-id(key('index1',@name)[1])]">
            <object><xsl:value-of select="@name"/></object>
        </xsl:for-each>
        </objects>
    </xsl:template>

</xsl:stylesheet>

这里发生了什么：

1. 使用<xsl:key name="index1" match="*" use="@name" />，您可以为名为@9​​87654325@ 的key() 函数定义一个索引。它必须在 xsl:template 声明之外。
2. 使用match="*"，您可以定义它适用于所有元素。
3. 使用use="@name"，您可以定义index1 的搜索条件。
4. 现在key("index1","obj1") 将返回一个由属性@name 等于"obj1" 的节点组成的数组：[<object name="obj1" id="id1"/>,<object name="obj1" id="id3"/>]。
5. 您将需要generate-id() 函数来为给定节点生成唯一 ID。
6. 使用参数调用，generate-id(<object name="obj1" id="id1"/>) 将返回类似"id0xfffffffff6ddca80obj1"。
7. 不带参数调用，generate-id() 将返回 当前 节点的 ID。
8. 您为所有元素//* 启动xsl:for-each 循环，条件是当前节点的generate-id() 必须等于key('index1',@name) 结果中第一个节点的generate-id()。这意味着它必须是第一个节点本身。
9. 您使用xsl:value-of 打印当前@name 值。由于它只发生在key('index1',@name) 结果的第一个元素上，因此只会打印一次。