Perl 中不区分大小写的唯一数组元素

Question

我正在使用模块导出的 uniq 函数 List::MoreUtils 来查找数组中的 uniq 元素。但是，我希望它以不区分大小写的方式查找 uniq 元素。我该怎么做？

我已经使用 Data::Dumper: 转储了数组的输出：

#! /usr/bin/perl

use strict;
use warnings;
use Data::Dumper qw(Dumper);
use List::MoreUtils qw(uniq);
use feature "say";

my @elements=<array is formed here>;

my @words=uniq @elements;

say Dumper \@words;

输出：

$VAR1 = [
          'John',
          'john',
          'JohN',
          'JOHN',
          'JoHn',
          'john john'
        ];

预期的输出应该是：john, john john

只有2个元素，其余的都应该过滤，因为它们是同一个词，只是大小写不同。

如何忽略大小写删除重复元素？

Answer 1

使用小写字母 lc 和 map 语句：

my @uniq_no_case = uniq map lc, @elements;

---

List::MoreUtils'uniq 区分大小写的原因是它依赖于哈希的重复数据删除特性，这也是区分大小写的。 uniq 的代码如下所示：

sub uniq {
    my %seen = ();
    grep { not $seen{$_}++ } @_;
}

如果你想在你自己的代码中直接使用这个 sub，你可以在里面合并lc：

sub uniq_no_case {
    my %seen = ();
    grep { not $seen{$_}++ } map lc, @_;
}

解释这是如何工作的：

@_ 包含子程序的参数，它们被馈送到grep 语句。通过代码块时返回 true 的任何元素都由 grep 语句返回。代码块包含一些更精细的点：

• $seen{$_}++ 在第一次看到元素时返回 0。该值仍会增加到 1，但在返回之后（而不是 ++$seen{$_} 会先增加，然后返回）。
• 通过否定递增的结果，我们得到第一个键的真值，而后面​​的每个键都为假。因此，该列表已删除重复数据。
• grep 作为 sub 中的最后一条语句将返回一个列表，该列表又由 sub 返回。
• map lc, @_ 只是将lc 函数应用于@_ 中的所有元素。

Answer 2

使用散列来跟踪您已经看过的单词，但也可以将它们标准化为大写/小写：

my %seen;
my @unique;
for my $w (@words) {
  next if $seen{lc($w)}++;
  push(@unique, $w);
}
# @unique has the unique words

请注意，这将保留原始单词的大小写。

更新：如 cmets 中所述，尚不清楚 OP 究竟需要什么，但我以这种方式编写解决方案是为了说明在某种“等价关系”下从列表中选择唯一代表的一般技术。在这种情况下，等价关系是单词$a 等效于单词$b 当且仅当lc($a) eq lc($b)。

大多数等价关系可以用这种方式表示，即关系由分类函数f()定义，使得$a等价于$b当且仅当f($a) eq f($b)。例如，如果我们想说如果两个词的长度相同，则它们是等价的，那么f() 将是length()。

所以现在你可能明白我为什么要这样写算法了——分类器函数可能不会产生原始列表中的值。在f = length的情况下，我们要选择单词，但是单词的f是一个数字。