检查字符串是否包含单词但仅在特定位置？

Question

如何检查字符串是否包含子字符串，但仅在特定位置？

示例字符串：

您最喜欢的颜色是什么？我的[最喜欢的]颜色是蓝色

如果我想检查字符串是否包含特定单词，我通常会这样做：

var
  S: string;
begin
  S := 'What is your favorite color? my [favorite] color is blue';
  if (Pos('favorite', S) > 0) then
  begin
    //
  end;
end;

我需要确定字符串中是否存在 favorite 这个词，忽略它是否出现在 [ ] 符号内，而上面的代码示例显然没有这样做。

因此，如果我们将代码放入布尔函数中，一些示例结果将如下所示：

TRUE：您最喜欢的颜色是什么？我的[我最喜欢的]颜色是蓝色

TRUE：您最喜欢的颜色是什么？我的 [blah blah] 颜色是蓝色

错误：你的 blah blah 是什么颜色？我的[一些最喜欢的]颜色是蓝色

上面的前两个示例是正确的，因为在 [ ] 符号之外发现了 favourite 这个词，无论它是否在其中。

第三个样本是假的，因为即使有 favourite 这个词，它也只出现在 [ ] 符号内 - 我们应该只检查它是否存在于符号之外。

所以我需要一个函数来确定一个单词（在这个例子中是最喜欢的）是否出现在字符串中，但是忽略这个单词是否被 [ ] 符号包围的事实。

Answer 1

我喜欢Sertac's idea 删除括号括起来的字符串并在此之后搜索字符串。这是一个通过搜索整个单词和区分大小写而扩展的代码示例：

function ContainsWord(const AText, AWord: string; AWholeWord: Boolean = True;
  ACaseSensitive: Boolean = False): Boolean;
var
  S: string;
  BracketEnd: Integer;
  BracketStart: Integer;
  SearchOptions: TStringSearchOptions;
begin
  S := AText;
  BracketEnd := Pos(']', S);
  BracketStart := Pos('[', S);
  while (BracketStart > 0) and (BracketEnd > 0) do
  begin
    Delete(S, BracketStart, BracketEnd - BracketStart + 1);
    BracketEnd := Pos(']', S);
    BracketStart := Pos('[', S);
  end;
  SearchOptions := [soDown];
  if AWholeWord then
    Include(SearchOptions, soWholeWord);
  if ACaseSensitive then
    Include(SearchOptions, soMatchCase);
  Result := Assigned(SearchBuf(PChar(S), StrLen(PChar(S)), 0, 0, AWord,
    SearchOptions));
end;

这是该函数的优化版本，它使用指针字符迭代而不进行字符串操作。与以前的版本相比，它可以处理缺少右括号的字符串的情况，例如My [favorite color is。由于缺少括号，因此该字符串被评估为 True。

原则是一个字符一个字符地遍历整个字符串，当你找到左括号时，看看那个括号是否有一个闭对。如果是，则检查从存储位置到左括号的子字符串是否包含搜索到的单词。如果是，则退出该功能。如果没有，请将存储的位置移动到右括号。如果左括号没有自己的右括号，则从存储位置到整个字符串的末尾搜索单词并退出函数。

此代码的注释版本follow this link。

function ContainsWord(const AText, AWord: string; AWholeWord: Boolean = True;
  ACaseSensitive: Boolean = False): Boolean;
var
  CurrChr: PChar;
  TokenChr: PChar;
  TokenLen: Integer;
  SubstrChr: PChar;
  SubstrLen: Integer;
  SearchOptions: TStringSearchOptions;
begin
  Result := False;
  if (Length(AText) = 0) or (Length(AWord) = 0) then
    Exit;
  SearchOptions := [soDown];
  if AWholeWord then
    Include(SearchOptions, soWholeWord);
  if ACaseSensitive then
    Include(SearchOptions, soMatchCase);
  CurrChr := PChar(AText);
  SubstrChr := CurrChr;
  SubstrLen := 0;
  while CurrChr^ <> #0 do
  begin
    if CurrChr^ = '[' then
    begin
      TokenChr := CurrChr;
      TokenLen := 0;
      while (TokenChr^ <> #0) and (TokenChr^ <> ']') do
      begin
        Inc(TokenChr);
        Inc(TokenLen);
      end;
      if TokenChr^ = #0 then
        SubstrLen := SubstrLen + TokenLen;
      Result := Assigned(SearchBuf(SubstrChr, SubstrLen, 0, 0, AWord,
        SearchOptions));
      if Result or (TokenChr^ = #0) then
        Exit;
      CurrChr := TokenChr;
      SubstrChr := CurrChr;
      SubstrLen := 0;
    end
    else
    begin
      Inc(CurrChr);
      Inc(SubstrLen);
    end;
  end;
  Result := Assigned(SearchBuf(SubstrChr, SubstrLen, 0, 0, AWord,
    SearchOptions));
end;

Answer 2

在regular expressions 中有一个叫look-around 的东西你可以使用。在你的情况下，你可以用消极的后视来解决它：你想要“最喜欢的”，除非它前面有一个左括号。它可能看起来像这样：

(?<!\[[^\[\]]*)favorite

一步一步：(?<! 是否定的lookbehind 前缀，我们正在寻找\[ 可选地后跟一个或多个不是右括号或左括号的东西：[^\[\]]*，用@987654327 关闭否定的lookbehind @，然后是favorite。

Answer 3

我认为您可以将您的问题改写为“发现所提供的字符串没有被方括号包围”。如果这描述了您的问题，那么您可以继续使用简单的正则表达式，例如 [^\[]favorite[^\]]。