在 TVirtualStringTree 的 InitNode 事件中分配字符串时访问冲突

Question

给定的代码在 Delphi 2007 中没有任何问题。但是在 Delphi 2009 中我遇到了异常。

访问冲突显示读取地址 $00000000。

问题只存在于分配字符串时，它适用于数字。

另外，当我通过调试器选项手动分配 Data.Text 时，我没有得到任何 AV - 它可以工作。

老实说，我迷路了，有人可以帮我解决这个问题吗？

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, VirtualTrees, StdCtrls;

type
  TTest = record
    Text: String;
    Number: Integer;
  end;
  PTest = ^TTest;

type
  TTestArray = array of TTest;

type
  TForm1 = class(TForm)
    VirtualStringTree1: TVirtualStringTree;
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
    procedure VirtualStringTree1InitNode(Sender: TBaseVirtualTree; ParentNode,
      Node: PVirtualNode; var InitialStates: TVirtualNodeInitStates);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  TestArray: array of TTest;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
  SetLength(TestArray, 1);
  TestArray[0].Text := 'test';
  TestArray[0].Number := 12345;
  VirtualStringTree1.AddChild(VirtualStringTree1.RootNode, @TestArray[0]);

end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  VirtualStringTree1.NodeDataSize := SizeOf(TTest);

end;

procedure TForm1.VirtualStringTree1InitNode(Sender: TBaseVirtualTree;
  ParentNode, Node: PVirtualNode; var InitialStates: TVirtualNodeInitStates);
var
  Data: PTest;
  NodeData: PPointer;
begin
  Data := Sender.GetNodeData(Node);
  NodeData := Sender.GetNodeData(Node);
  Data.Number := PTest(NodeData^)^.Number;
  Data.Text := PTest(NodeData^)^.Text; //crash here!
end;

end.

Answer 1

当您调用AddChild(..., @TestArray[0]) 时，您只是在初始化节点数据的前四个字节。那是Text 字段。 Text 字段包含一个指向 TTest 结构的指针。 应该持有一个string 引用。

GetNodeData 函数返回指向节点数据的指针。树控件分配了一个TVirtualNode 记录，紧接着，在连续内存中，它分配了NodeDataSize 字节供您使用，GetNodeData 返回该空间的地址。您应该将其视为指向 TTest 结构的指针。对于您的某些代码，您确实做到了。看起来您正试图绕过调用AddChild 时仅初始化结构的前四个字节的限制。 （我不能说我建议这样做。还有其他方法可以将数据与不需要太多类型双关的节点相关联。）

您为节点数据的使用方式正确分配了Data。您将NodeData 正确分配给它在初始化时真正 持有的东西——一个指向TTest 结构的指针的指针。您正确地取消引用 NodeData 以读取 Number 字段，并且您还正确读取 Text 字段。但是，Data.Text 字段不能按照您的方式覆盖：

Data.Text := PTest(NodeData^)^.Text;

Data.Text 字段当前不包含有效的 string 值，但 string 变量需要始终保持有效值（或至少在存在它们可能会被读取或写入）。要分配string 变量，程序会增加新值的引用计数并减少旧值的引用计数，但由于在这种情况下“旧值”并不是真正的string，因此没有有效引用计数递减，即使有，该位置的内存也无法释放——它属于TestArray。

不过，有办法解决这个问题。分两步复制字符串。首先，将NodeData.Text 中的值读取到备用string 变量中。一旦你这样做了，你就不再需要NodeData，所以你可以覆盖它指向的值。如果将其设置为所有位为零，那么您也将隐式覆盖Data.Text，并使用空字符串的值。此时，将 覆盖为 string 变量是安全的：

tmp := PTest(NodeData^)^.Text;
PTest(NodeData^) := nil;
Data.Text := tmp;

解决此问题的另一种方法是重新排列节点数据中字段的顺序。将Integer 字段放在第一位，然后初始化Data.Number 最后而不是Data.Text。 Integer 值始终可以安全地覆盖，无论其内容如何。

无论你做什么，确保你敲定OnFreeNode事件中的记录：

var
  Data: PTest;
begin
  Data := Sender.GetNodeData;
  Finalize(Data^);
end;

这样可以确保 string 字段在必要时减少其引用计数。

Answer 2

你在这里错过了重点。您已经在按钮的单击事件上初始化了您的节点，因此无需另外使用OnInitNode 来初始化它。您需要的可能是使用OnGetText 来显示您的数据。例如：

procedure TForm1.VirtualStringTree1GetText(Sender: TBaseVirtualTree; Node: PVirtualNode;
  Column: TColumnIndex; TextType: TVSTTextType; var CellText: string);
var
  Data: PTest;
begin
  Data := PTest(Sender.GetNodeData(Node)^);

  CellText := Data.Text;
end;