通用工厂循环

Question

我想弄清楚如何在 XE2 中编写通用工厂。假设我有这个：

type
  TObjectTypes = (otLogger, otEmail);

type
  TLoggerTypes = (lFile, lConsole, lDatabase);

type
  TEmailTypes = (etPOP3, etSMTP);

类：

TSMTPEmail = class(TInterfacedObject, IEmail); // Supports emailing only
TPOP3Email = class(TInterfacedObject, IEmail); // Supports emailing only
TFileLogger = class(TInterfacedObject, ILogger); // Supports logging only

等等

现在我这样做是为了遍历所有 TObjectTypes：

procedure TForm1.FormCreate(Sender: TObject);
var
  _Interf: IInterface;
  _Configuration: TDictionary<string, TValue>;
  _ObjectType: TObjectTypes;
begin
  _Configuration := nil;
  _Configuration := TDictionary<string, TValue>.Create;
  try
    _Configuration.Add('FileLogFileName', '20160320.Log');
    _Configuration.Add('SMTPEmailHost', 'mail.server.lt');
    _Configuration.Add('POP3Server', 'some_server');

    for _ObjectType := Low(TObjectTypes) to High(TObjectTypes) do
    begin
      _Interf := TTheFactory.Make(_ObjectType, _Configuration);
      if Assigned(_Interf) then
      begin
        OutputDebugString(PWideChar((_Interf as TObject).ClassName));
        if Supports(_Interf, IEmail) then
          (_Interf as IEmail).Send('X');

        if Supports(_Interf, ILogger) then
          (_Interf as ILogger).GetLastErrorMsg;
      end;
    end;
  finally
    FreeAndNil(_Configuration);
  end;
end;

所以，我需要一个通用工厂，并且能够不通过所有 TObjectTypes 循环，而是通过所有 TLoggerTypes 或通过所有 TEmailTypes 并跳过创建一些例如lDatabase 来自 TLoggerTypes 或 etPOP3 来自 TEmailTypes。

工厂应该生产各种类。

Answer 1

在 Delphi 中制造工厂非常简单，这要归功于元类（类引用），其中的简单示例是 TClass：

TClass = class of TObject

在大多数情况下，您应该为所有工厂成员定义自己的抽象类并为其定义元类：

TMyFactoryObject = class (TObject)
  public
    constructor FactoryCreate(aConfiguration: TConfiguration); virtual; abstract;
end;

TMyFactoryClass = class of TMyFactoryObject;

在这个抽象类中，您可以添加一些对所有后代通用的方法，在我的示例中，我们有将配置作为参数的构造函数。如何应对，将由后代决定。

然后你声明后代类：

TMyLogger = class (TMyFactoryObject, ILogger)
  private
    ...
  public
    constructor FactoryCreate(aConfiguration: TConfiguration); override;
    ... //implementation of ILogger interface etc
  end;

TMyEmail = class (TMyFactoryObject, IEmail)
  private
    ...
  public
    constructor FactoryCreate(aConfiguration: TConfiguration); override;
    ... //implementation of IEmail interface etc
  end;

现在您声明了可能的后代类数组：

var 
  MyFactory: array [otLogger..otEmail] of TMyFactoryClass;

并在初始化部分或其他地方填充此数组：

MyFactory[otLogger]:=TMyLogger;
MyFactory[orEmail]:=TMyEmail;

最后，您问题中的TTheFactory.Make(_ObjectType, _Configuration); 可以替换为：

MyFactory[_ObjectType].FactoryCreate(_Configuration);

您将获得所需的对象作为 MyFactoryObject 类型的实例。

更多信息请参见http://docwiki.embarcadero.com/RADStudio/Seattle/en/Class_References。