使用 delphi 从 .log 文件中读取时获取“ÿþI”作为输出数据

Question

我正在尝试从 .log 文件中读取数据并处理其内容。日志文件由另一个应用程序创建。当我在 Delphi 中使用 readln 命令并在备忘录中显示文件内容时，我只能从包含超过 6000 行数据的文件中获取一行数据（ÿþI）。

    procedure TForm1.Button1Click(Sender: TObject);
    Var
        F : TextFile;
        s : string;
    begin
        AssignFile(F, 'data.log');
        Reset(F);

        while not Eof(F) do
        begin
            Readln(F, s);
            Memo1.Lines.Add(s);
        end;
    end;

有人知道问题出在哪里吗？

Answer 1

正如迈克尔所说，您正在处理一个 UTF-16 编码的文件，因此您必须手动加载和解码它。网上有各种基于WideString 的TStringList 类类，或者Borland 在WideStrings 单元中有自己的实现，请尝试使用其中之一来代替Pascal 文件I/O，例如：

procedure TForm1.Button1Click(Sender: TObject);
var
  SL : TWideStringList;
  I: Integer;
  s : string;
begin
  SL := TWideStringList.Create;
  try
    SL.LoadFromFile('data.log');
    Memo1.Lines.BeginUpdate;
    try
      for I := 0 to SL.Count-1 do
        Memo1.Lines.Add(SL[I]);
    finally
      Memo1.Lines.EndUpdate;
    end;
  finally
    SL.Free;
  end;
end; 

或者：

uses
  .., WideStrings;

procedure TForm1.Button1Click(Sender: TObject);
var
  SL : TWideStringList;
begin
  SL := TWideStringList.Create;
  try
    SL.LoadFromFile('data.log');
    Memo1.Lines.Assign(SL);
  finally
    SL.Free;
  end;
end; 

或者，安装 TNTWare 或 TMS 的副本，它们都具有支持 Unicode 的组件。然后您应该能够将LoadFromFile() .log 文件直接输入您选择使用的 Unicode 备忘录组件。

Answer 2

您正在处理一个 UTF-16 文件（如前两个字符所示），而 Delphi 2007 并没有为此做好准备，因此它在第一个 $0 字节处停止读取，因为 Readln 认为该行结束在那里。

您需要使用不同的方法来读取文件，并且您必须读取到 WideString（并可能将其转换为字符串）。由于 Delphi 2007 不支持 Unicode，我认为您还必须进行自己的行拆分，但我这里没有，所以我不完全确定。

Answer 3

正如我在对 Remy 的回答的评论中提到的，在 WideStrings 中声明了一个 TWideStrings/TWideStringList：

uses WidesStrings;
//...
var
  Ws: TWideStrings;
  s: string;
  i: Integer;
begin
  Ws := TWideStringList.Create;
  try
    ws.LoadFromFile('C:\temp\UniTest.txt');
    for i := 0 to ws.Count - 1 do
    begin
      s := ws[i];
      Memo1.Lines.Add(s);
    end;
  finally
    ws.Free;
  end;
end;

但请注意，它不是TStrings 的后代，因此不能直接将其分配给 TMemo.Lines 之类的 TStrings 属性，您必须一一添加。

它似乎也无法处理 BOM（您的 ÿþ）或大端编码