你如何覆盖委托的方法实现？

Question

在 Delphi 2007 中，我使用一个类来实现第二类支持的接口之一。这是有效的。 Delphi 帮助指出：

默认情况下，使用 implements 关键字代表所有接口 方法。但是，您可以使用方法解析子句或声明 类中实现某些接口方法的方法 覆盖此默认行为。

但是，当我在我的第二个类中声明一个具有与其中一个接口方法匹配的签名的方法时，它不会被调用。

我想知道这是不是因为我在创建该类时通过另一个接口访问它。

下面是一个演示我的问题的测试程序：

program Project1;

{$APPTYPE CONSOLE}

type
  IInterface1 = interface
  ['{15400E71-A39B-4503-BE58-B6D19409CF90}']
    procedure AProc;
  end;

  IInterface2 = interface
  ['{1E41CDBF-3C80-4E3E-8F27-CB18718E8FA3}']
  end;

  TDelegate = class(TObject)
  protected
    procedure AProc;
  end;

  TMyClass = class(TInterfacedObject, IInterface1, IInterface2)
  strict private
    FDelegate: TDelegate;
    property Delegate: TDelegate read FDelegate implements IInterface1;
  public
    constructor Create;
    destructor Destroy; override;
    procedure AProc;
  end;

procedure TDelegate.AProc;

begin
  writeln('TClassDelegate.AProc');
end;

constructor TMyClass.Create;
begin
  inherited;
  FDelegate := TDelegate.Create;
end;

destructor TMyClass.Destroy;
begin
  FDelegate.Free;
  inherited;
end;

procedure TMyClass.AProc;

begin
  writeln('TMyClass.AProc');
end;

var
  MyObj : IInterface2;

begin
    MyObj := TMyClass.Create;
   (MyObj as IInterface1).AProc;
end.

当我运行它时，我得到了输出：

TClassDelegate.AProc

我想要的是：

TMyClass.AProc

任何帮助表示赞赏。

Answer 1

看来你必须以这种方式重新声明你的方法：

TMyClass = class(TInterfacedObject, IInterface1, IInterface2)
strict private
  ....
  procedure test();
public
  ....
  procedure  IInterface1.AProc = test;
end;

procedure TMyClass.test;
begin
  writeln('TMyClass.AProc');
end;

所以IInterface1.AProc for TMyClass 映射到Test()（而不是FDelegate.AProc） 结果是TMyClass.AProc

Answer 2

documentation 明确指出您看到的行为是设计好的：

如果委托属性是类类型，则在搜索该类及其祖先之前搜索实现指定接口的方法，然后搜索封闭类及其祖先。

我猜在完整示例中，您有一个包含多个方法的接口，并且想要委托指定的大多数方法，以及由实现类覆盖的特定方法。我看不出如何只用一个类来实现这一点，但如果你引入第二个类就可以做到：

program Project1;

{$APPTYPE CONSOLE}

type
  IInterface1 = interface
  ['{15400E71-A39B-4503-BE58-B6D19409CF90}']
    procedure AProc;
    procedure AnotherProc;
  end;

  TDelegate = class
  protected
    procedure AProc;
    procedure AnotherProc;
  end;

  TMyClass = class(TInterfacedObject, IInterface1)
  strict private
    FDelegate: TDelegate;
    property Delegate: TDelegate read FDelegate implements IInterface1;
  public
    constructor Create;
    destructor Destroy; override;
    procedure AProc;
  end;

  TMyOtherClass = class(TMyClass, IInterface1)
    procedure IInterface1.AProc = AProc;
  end;

procedure TDelegate.AProc;
begin
  writeln('TDelegate.AProc');
end;

procedure TDelegate.AnotherProc;
begin
  writeln('TDelegate.AnotherProc');
end;

constructor TMyClass.Create;
begin
  inherited;
  FDelegate := TDelegate.Create;
end;

destructor TMyClass.Destroy;
begin
  FDelegate.Free;
  inherited;
end;

procedure TMyClass.AProc;
begin
  writeln('TMyClass.AProc');
end;

var
  MyObj: IInterface1;

begin
  MyObj := TMyOtherClass.Create;
  MyObj.AProc;
  MyObj.AnotherProc;
  Readln;
end.

正如@teran 指出的那样，如果您准备重命名您的方法，那么有一个更简单的解决方案。

Answer 3

这可能是由于属性的可见性。每次我使用implements 时，属性都是protected 或public，对于我可以在VCL 中找到的所有示例（例如TAutoObjectEvent。

尝试 #2：

如果从TMyClass 中删除AProc() 方法会发生什么？然后它会使用TDelegate 上的那个吗？

Answer 4

您提到的文档部分似乎已过时。如果您尝试对implements 子句中使用的接口使用方法解析，您将收到编译器错误E2264: Cannot have method resolutions for interface '%s'。

上面链接中显示的解决方案 - 简单地将过程与接口中声明的名称相同 - 在 Delphi XE 中似乎也不起作用（它编译但不调用过程）。