问题：
有没有办法使用 Delphi 2007 进行鸭式打字（即没有泛型和高级 Rtti 功能）？
用于 Delphi 2010 及以后的鸭子打字资源：
上次编辑：
我对上面列出的资源进行了深入研究，并在此处研究了每个发布的答案。
我最终完善了我的要求，并为此问题提出了follow up post。
【问题讨论】：
标签： delphi delphi-2007 duck-typing
在 ObjAuto.pas 和可调用变体类型的帮助下，它应该是可能的（用 XE 编写，但也应该在 Delphi 7 或更低版本中运行）：
unit DuckTyping;
interface
function Duck(Instance: TObject): Variant;
implementation
uses
ObjAuto,
SysUtils,
TypInfo,
Variants;
type
TDuckVarData = packed record
VType: TVarType;
Reserved1, Reserved2, Reserved3: Word;
VDuck: TObject;
Reserved4: LongWord;
end;
TDuckVariantType = class(TPublishableVariantType)
protected
function GetInstance(const V: TVarData): TObject; override;
public
procedure Clear(var V: TVarData); override;
procedure Copy(var Dest: TVarData; const Source: TVarData;
const Indirect: Boolean); override;
function DoFunction(var Dest: TVarData; const V: TVarData;
const Name: string; const Arguments: TVarDataArray): Boolean; override;
end;
var
DuckVariantType: TDuckVariantType;
{ TDuckVariantType }
procedure TDuckVariantType.Clear(var V: TVarData);
begin
V.VType := varEmpty;
TDuckVarData(V).VDuck := nil;
end;
procedure TDuckVariantType.Copy(var Dest: TVarData; const Source: TVarData;
const Indirect: Boolean);
begin
if Indirect and VarDataIsByRef(Source) then
VarDataCopyNoInd(Dest, Source)
else
begin
with TDuckVarData(Dest) do
begin
VType := VarType;
VDuck := TDuckVarData(Source).VDuck;
end;
end;
end;
function TDuckVariantType.DoFunction(var Dest: TVarData; const V: TVarData;
const Name: string; const Arguments: TVarDataArray): Boolean;
var
instance: TObject;
methodInfo: PMethodInfoHeader;
paramIndexes: array of Integer;
params: array of Variant;
i: Integer;
ReturnValue: Variant;
begin
instance := GetInstance(V);
methodInfo := GetMethodInfo(instance, ShortString(Name));
Result := Assigned(methodInfo);
if Result then
begin
SetLength(paramIndexes, Length(Arguments));
SetLength(params, Length(Arguments));
for i := Low(Arguments) to High(Arguments) do
begin
paramIndexes[i] := i + 1;
params[i] := Variant(Arguments[i]);
end;
ReturnValue := ObjectInvoke(instance, methodInfo, paramIndexes, params);
if not VarIsEmpty(ReturnValue) then
VarCopy(Variant(Dest), ReturnValue);
end
else
begin
VarClear(Variant(Dest));
end;
end;
function TDuckVariantType.GetInstance(const V: TVarData): TObject;
begin
Result := TDuckVarData(V).VDuck;
end;
function Duck(Instance: TObject): Variant;
begin
TDuckVarData(Result).VType := DuckVariantType.VarType;
TDuckVarData(Result).VDuck := Instance;
end;
initialization
DuckVariantType := TDuckVariantType.Create;
finalization
FreeAndNil(DuckVariantType);
end.
您可以像这样简单地使用它：
type
{$METHODINFO ON}
TDuck = class
public // works in XE, not sure if it needs to be published in older versions
procedure Quack;
end;
procedure TDuck.Quack;
begin
ShowMessage('Quack');
end;
procedure DoSomething(D: Variant);
begin
D.Quack;
end;
var
d: TDuck;
begin
d := TDuck.Create;
try
DoSomething(Duck(d));
finally
d.Free;
end;
end;
【讨论】：
快速回答：
更长的答案：根据wiki page“Duck Typing”的标识：
在鸭子类型中，人们只关心对象的那些被使用的方面，而不是对象本身的类型。例如，在非鸭子类型语言中，可以创建一个函数，该函数接受一个鸭子类型的对象并调用该对象的 walk 和 quack 方法。在鸭子类型语言中，等效函数将获取任何类型的对象并调用该对象的 walk 和 quack 方法。如果对象没有被调用的方法，则该函数会发出运行时错误信号。
等效的 Delphi 不可编译代码如下所示：
procedure DoSomething(D);
begin
D.Quack;
end;
我故意没有为D 指定类型，因为那样会破坏目的。 Delphi 是静态类型的，所以这永远不会工作。如果您需要此功能来实现一些小功能，您可以使用 Interfaces 或 RTTI 并获得如下内容：
procedure DoSomething(D:TObject);
begin
(D as ISomeIntf).Quack;
end;
如果你能获得 RTTI：
procedure DoSomething(D:TObject);
begin
CallQuackUsingRTTI(D);
end;
我个人使用RTTI 方法来识别（和操作）列表对象，使代码同时适用于TList 后代和通用TList<T> 变体。
从中得出的结论应该是：即使在最新版本的 Delphi 中具有高级功能（泛型和综合 RTTI），您也只能在有限的功能和大量努力下接近 Duck 打字。这根本不在 Delphi 的 DNA 中（因为 Delphi 的 DNA 说“静态类型”），但您可能能够获得足够接近的东西，并且付出很多努力，并且仅用于特定功能.也许如果您告诉我们您想要什么具体功能，我们就能想出办法。
【讨论】：
function Count: Integer; 2) function GetItem(const index: Integer): TObject; 3) procedure Add(const AObject: TObject); 4) procedure Clear; 的任意列表对象。
Supports()检查列表对象是否实现了这个接口。
这是一个需要您创建类型库的想法。
使用 OLE 自动化类型，并实现调度接口（双 COM 对象）。
现在你现在你可以在该类型之后编写任何你想要的东西，我们将在运行时找出它是否有效或崩溃。欢迎使用动态类型。
procedure DoSomething(D:OleVariant);
begin
D.Quack; // Might work, might blow up.
end;
我认为它丑陋，但其他人可能不会。
【讨论】：