如何防止列表视图在 item.count 更改时跳转到选定/焦点行？

Question

我有一个虚拟列表视图，我打算用它来显示一个相当大的日志文件中的内容。

每当添加或删除一行时，我在列表框中选择或聚焦（或两者）行，它会自动滚动回它，这很烦人。

当项目计数被修改时，感觉就像有东西在调用 MakeVisible（或做同样事情的东西）。

重现它的非常简化的示例：

procedure TForm1.FormCreate(Sender: TObject);
var
  Col: TListColumn;
begin
  ListView1.OwnerData := True;
  ListView1.ViewStyle := vsReport;
  ListView1.RowSelect := True;

  Col := ListView1.Columns.Add;
  Col.Caption := 'LineNum';
  Col.Alignment := taLeftJustify;
  Col.Width := 70;
end;
// listview onData event
procedure TForm1.ListView1Data(Sender: TObject; Item: TListItem);
begin
  Item.Caption := IntToStr(Item.Index+1);
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  ListView1.Items.Count := ListView1.Items.Count + 10;
end;

编辑：测试不同的 ViewStyles，这只发生在 vsReport 和 vsList

Answer 1

问题在于TListItems.Count 属性设置器调用ListView_SetItemCountEx() 时没有LVSICF_NOSCROLL 标志：

当项目计数改变时，列表视图控件不会改变滚动位置。

procedure TListItems.SetCount(Value: Integer);
begin
  if Value <> 0 then
    ListView_SetItemCountEx(Handle, Value, LVSICF_NOINVALIDATEALL)
  else
    ListView_SetItemCountEx(Handle, Value, 0);
end;

这就是 ListView 在Count 更改时滚动的原因。您必须自己直接致电ListView_SetItemCountEx()，以便指定LVSICF_NOSCROLL 标志。

uses
  ..., CommCtrl;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  //ListView1.Items.Count := ListView1.Items.Count + 10;
  ListView_SetItemCountEx(ListView1.Handle, ListView1.Items.Count + 10, LVSICF_NOINVALIDATEALL or LVSICF_NOSCROLL);
end;