在delphi SDI中创建新表单时传递参数

Question

好的，如果这有点令人困惑，我很抱歉，但我不知道如何更好地解释它。我有一个聊天表单，在用户之前在 TLoginForm 中进行身份验证后显示。

用户登录后显示chatForm：

with TChatForm.Create(Application) do
begin
    Show;
end;

我的问题是，考虑到表单自动连接到服务器 OnShow 的事实，我如何将用户名传递给 chatForm 以便我可以在聊天中使用它作为昵称，所以我需要已经发送的用户名。

我是 delphi 新手，如果我的代码有任何错误，请见谅。

Answer 1

如果用户名在对象的整个生命周期内应该是固定的，那么它应该被传递给构造函数。好处是不可能误用类而忘记分配用户名。

声明一个构造函数，接收参数中的额外信息：

type
  TMyForm = class(TForm)
  private
    FUserName: string;
  public
    constructor Create(AOwner: TComponent; 
        const UserName: string);
  end;

constructor TMyForm.Create(AOwner: TComponent; 
        const UserName: string);
begin
  inherited Create(AOwner);
  FUserName := UserName;
end;

像这样创建表单：

MyForm := TMyForm.Create(Application, UserName);

Answer 2

向您的聊天表单添加公共方法。

with TChatForm.Create(Application) do
begin
  PassUserName(FUsername);
  Show;
end;

procedure TChatForm.PassUserName(const aUsername: string);
begin
  Caption := 'You can now chat: '+ aUsername;
end;

这使您可以在聊天表单中传递您想要的任何内容，而无需更改现有的公共方法，只需添加新方法即可。
不使用“with”或 FUsername 来解决问题的示例：

frmChat := TChatForm.Create(Application);
frmChat.Nickname := aUsername;
frmChat.Show;

TChatForm = class(TForm)
private
  FUsername : string;

  procedure SetNickName(const Value: string);
  function GetNickName: string;
public
  property NickName: string read GetNickName write SetNickName;
end;

procedure TChatForm.SetNickName(const Value: string);
begin
  FUsername := Value;
end;
function TChatForm.GetNickName: string;
begin
  Result := FUsername;
end;