FPC 和 Delphi 之间的字符串

Question

我在 Delphi 中从 FPC DLL 获取 String 的长度时遇到问题。这很奇怪，因为我可以从 DLL 中取回 String，但我无法获得它的长度。

德尔福：

program Project2;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils;

function Test(const S: String): Integer; cdecl; external 'c:\Project1.dll';

var
    A: String;
begin 
    A := 'test';
    WriteLn(Test(A)); // 1 ?
    ReadLn;
end.

FPC：

library project1;

{$mode ObjFPC}{$H+}

uses
  Classes;

function Test(const A: String): Integer; cdecl; export;
begin
 Result := Length(A);
end;

exports Test;

end.

Answer 1

String 在 Delphi 2009+ 中是 UnicodeString，在早期版本中是 AnsiString。

FPC 中的String 始终为AnsiString，它从不映射到UnicodeString。而且 AFAIK，FPC 的字符串类型无论如何都不是与 Delphi 的字符串类型二进制兼容的。所以你不能将 Delphi AnsiString 传递给 FPC AnsiString，反之亦然，UnicodeString 也是如此。

无论如何，您都不应该在 DLL 边界上传递 String 值，尤其是在涉及多个编译器时，尤其是因为您没有使用 FPC 的 Delphi 模式。您需要重新设计您的 DLL 以使其更具可移植性，例如：

FPC：

library project1;

{$mode ObjFPC}
{$H+}

uses
  Classes;

function TestA(const A: PAnsiChar): Integer; cdecl; export;
begin
 Result := Length(A);
end;

function TestW(const A: PWideChar): Integer; cdecl; export;
begin
 Result := Length(A);
end;

exports TestA, TestW;

end.

德尔福：

program Project2;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils;

function Test(const S: PChar): Integer; cdecl; external 'Project1.dll' name {$IFDEF UNICODE}'TestW'{$ELSE}'TestA'{$ENDIF};

var
  A: String;
begin 
  A := 'test';
  WriteLn(Test(PChar(A)));
  ReadLn;
end.

Answer 2

您不能在此模块边界上使用string。 Delphi 类型与 FPC 类型完全不同。的确，它们具有相同的名称，但这并不意味着它们是同一类型。

事实上，即使两个模块都是用同一个编译器编译的，它们也会是不同的类型，分配在不同的堆上并且对互操作无效。在 Delphi 中，您可以使用 Sharemem 和完全相同的编译器版本，但这非常受限制。

使用互操作友好的类型，例如 PWideChar 用于 UTF-16 或 PAnsiChar 用于 UTF-8。这样你的库就不会受到限制，并且可以与任何东西互操作。