这是某种魔法……还是虫子？ [关闭]

Question

我将我的程序添加到了 SendTo。我向它发送了两个文件。 它们是：

C:\ThisIsMySuperTestHelloWorld\ThisBookIsRedMyPenIsWhite\test.jpg
C:\ThisIsMySuperTestHelloWorld\ThisBookIsRedMyPenIsWhite\hello.jpg

下面的代码显示C:\ThisIsMySuperTestHelloWorld\ThisBookIsRedMyPenIsWhite\test.jpg@C:\ThisIsMySuperTestHelloWorld\ThisBookIsRedMyPenIsWhite\test.jpg

procedure TForm1.FormCreate(Sender: TObject);
var Files: array of PAnsiChar;
    i: Integer;
begin
  SetLength(Files, 2);

  for i:=0 to 1 do begin
   Files[i] := PAnsiChar(ParamStr(2+i));
  end;

  ShowMessage( Files[0] +'@' + Files[1] );
end;

我在 Windows7 上使用 Delphi 6。 在 Delphi Xe3（仍然是 Win7）下，我将（两者）PAnsiChar 更改为 PWideChar，效果相同。

我的 SendTo 链接链接到：

"C:\<PATH_HERE>\Project1.exe" c

并放置在这里：

C:\Users\<USER>\AppData\Roaming\Microsoft\Windows\SendTo

Answer 1

使用字符串怎么样？例如：

procedure HandleParams;
var Files: array of string;
    i: Integer;
begin
  SetLength(Files, ParamCount);
  for i := 1 to ParamCount do
        Files[i-1] := ParamStr(i);

  if ParamCount >= 2 then
        ShowMessage( Files[0] +'@' + Files[1] );
end;

您的代码不起作用，因为 PAnsiChar 只是一个指针，不存储实际的字符串数据。当您分配从 ParamStr 函数返回的字符串时，仅存储指向（临时）函数结果的指针。实际数据将被下一个函数调用覆盖。这甚至会在进一步使用时使您的程序崩溃。

顺便说一句，您的 ParamStr 索引迭代了 2 和 3，并引用了第二个和第三个参数；也许这不是预期的，因为参数从索引 1 开始（索引 0 是程序调用本身）？

要解决这个问题，必须存储字符串数据，这使得指针有点没用，但无论如何，这是你示例的固定版本：

procedure HandleParamsPAnsi;
var Files: array of PAnsiChar;
    FilesData: array of AnsiString;
    i: Integer;
begin
  SetLength(Files, 2);
  SetLength(FilesData, 2);

  for i:=0 to 1 do begin
      FilesData[i] := AnsiString(ParamStr(1+i));
      Files[i] := PAnsiChar(FilesData[i]);
  end;

  ShowMessage( Files[0] + '@' + Files[1] );
end;