当互联网变慢时，TIdHttp 冻结

Question

如何避免在互联网变慢或无连接时冻结 idHTTP。我的应用程序被冻结，我什至无法关闭表单。

这就是我设置代码的方式

procedure TDownloader.IdHTTPWork(ASender: TObject; AWorkMode: TWorkMode;
  AWorkCount: Int64);
var
  lwElapsedMS: LongWord;
  iBytesTransferred: Int64;
  iBytesPerSec: Int64;
  iRemaining: Integer;
begin
  if AWorkMode <> wmRead then Exit;

  lwElapsedMS := GetTickDiff(FLastTicks, Ticks);
  if lwElapsedMS = 0 then lwElapsedMS := 1; // avoid EDivByZero error

  if FTotalBytes > 0 then
    FPercentDone := Round(AWorkCount / FTotalBytes * 100.0)
  else
    FPercentDone := 0;

  iBytesTransferred := AWorkCount - FLastWorkCount;

  iBytesPerSec := Round(iBytesTransferred * 1000 / lwElapsedMS);

  if Assigned(OnDownloadProgress) then
  begin
    if FContinueDownload <> 0 then //previous file downloaded
    begin
      iRemaining := 100 - FContinueDownload;
      iRemaining := Round(FPercentDone * iRemaining / 100);
      OnDownloadProgress(Self, FContinueDownload + iRemaining, AWorkCount, FTotalBytes, iBytesPerSec);
    end else
      OnDownloadProgress(Self, FPercentDone, AWorkCount, FTotalBytes, iBytesPerSec);
  end;

  FLastWorkCount := AWorkCount;
  FLastTicks := Ticks;

  if FCancel then
  begin
    Abort;
    TidHttp(ASender).Disconnect;
  end;
end;

procedure TDownloader.IdHTTPWorkBegin(ASender: TObject; AWorkMode: TWorkMode;
  AWorkCountMax: Int64);
begin
  if AWorkMode <> wmRead then Exit;

  FPercentDone := 0;
  FTotalBytes := AWorkCountMax;
  FLastWorkCount := 0;
  FLastTicks := Ticks;
end;

procedure TDownloader.IdHTTPWorkEnd(ASender: TObject; AWorkMode: TWorkMode);
begin
  if AWorkMode <> wmRead then Exit;
  if Assigned(OnDownloadComplete) and (FPercentDone >= 100) then
    OnDownloadComplete(Self)
  else if Assigned(OnDownloadCancel) then
    OnDownloadCancel(Self);
end;

function TDownloader.EXDownload(AURL, ADestFile: String;
  AAutoDisconnect: Boolean): Boolean;
var
  fsBuffer: TFileStream;
  idHttp: TIdHttp;
begin
  if FileExists(ADestFile) then
    fsBuffer := TFileStream.Create(ADestFile, fmOpenReadWrite)
  else
    fsBuffer := TFileStream.Create(ADestFile, fmCreate);

  fsBuffer.Seek(0, soFromEnd);
  try
    idHttp := TIdHttp.Create(nil);
    idHttp.OnWorkBegin := idHttpWorkBegin;
    idHttp.OnWork := idHttpWork;
    idHttp.OnWorkEnd := idHttpWorkEnd;
    idHttp.Request.CacheControl := 'no-store';
    try
      ...
      idHttp.Get(AURL, fsBuffer);
      ...
    finally
      idHttp.Free;
    end;
  finally
    fsBuffer.Free;
  end;
end;

……

procedure TDownloader.Execute;
begin
  Inherited;
  while not Terminated do
  begin
    if FUrl <> '' then
    begin
      EXDownload(FUrl, FFilename, True);
    end;
  end;
end;

... 关于主窗体进度

procedure TfrmDownloadList.DownloadProgress(Sender: TObject; aPercent:Integer;
    aProgress, aProgressMax, aBytesPerSec: Int64);
var
  yts: PYoutubeSearchInfo;
begin
  if Assigned(FCurrentDownload) then
  begin
    yts := vstList.GetNodeData(FCurrentDownload);
    yts.Tag := aPercent;
    ProgressBar.Position := aPercent;
    vstList.InvalidateNode(FCurrentDownload);
    StatusBar.Panels.Items[1].Text := 'Download: ' + FormatByteSize(aProgress) + '/' +
      FormatByteSize(aProgressMax);
    StatusBar.Panels.Items[2].Text := 'Speed: ' + FormatByteSize(aBytesPerSec) + 'ps';
    Application.ProcessMessages;
  end;
end;

只有当网络由于信号不佳而下降时，我才没有问题。 这是我的应用程序lookslike

Answer 1

如果我们假设 TDownloader.OnDownloadProgress 分配给 TfrmDownloadList.DownloadProgress 方法，那么您的问题是您正在从辅助线程（即不是从主线程）调用 VCL 代码（您更新进度条） .不支持。

您需要使用线程内的 Synchronize 语句来包装调用。 Synchronize 在主线程上调用无参数方法。因此，您需要存储所需的变量，然后对 TDownloader 类中的方法调用 Synchronize，然后调用 TfrmDownloadList.DownloadProgress

您不能直接或间接从在主线程以外的另一个线程上运行的代码中调用 TfrmDownloadList.DownloadProgress，因为它会更新 VCL 对象，而且 VCL 不是线程安全的。

您的 DownloadComplete 事件也是如此，如果它更新任何 VCL 对象...

Answer 2

你用 TIdAntiFreeze 怎么样？

TIdAntiFreeze 实现了一个 GUI 集成类，可确保 处理器时间分配给应用程序主线程。

Indy 使用阻塞套接字模型。调用中的方法 Indy 组件在完成之前不会返回。如果来电 在主线程中进行，这将导致应用程序用户 在 Indy 通话期间“冻结”的界面。 TIdAntiFreeze 中和 这种效果。

TIdAntiFreeze 允许 Indy 处理应用程序消息，以便 Windows 消息在 Indy 阻塞套接字时继续执行 通话生效。

一个应用程序中只能有一个 TIdAntiFreeze 处于活动状态。