如何使用 TIdHttp GET 请求发送内容？

Question

我正在尝试访问具有使用 GET 动词的端点的 REST 服务器，同时它还需要在正文中发送 json 数据

我正在尝试使用 Get 方法通过 TIdHttp 类来实现。

现在我用 json 数据创建一个 TStringStream，然后将该流分配给 TIdHttp 对象的 Request.Source 属性。

但是，服务器以错误代码响应，表明它没有收到正文。

如何使用 TIdHttp 发送带有 GET 请求的正文？

Answer 1

正如 Remy 建议的那样，您可以破解一个“访问器”类，以设法通过类型强制调用来访问此方法。

或者，您可以简单地继承 TIdHttp 并添加一个适当的新 Get() 便利方法，遵循为所有其他此类建立的模式方法。

例如类似：

interface

  type
    TOurHttp = class(TIdHttp)
    public
      procedure Get(aUrl: String; aRequestBody, aResponseContent: TStream);
    end;

implementation

  procedure TOurHttp.Get(aUrl: String; aRequestBody, aResponseContent: TStream);
  begin
    DoRequest(Id_HttpMethodGet, aUrl, aRequestBody, aResponseContent, []);
  end;

这是我们在我之前工作过的一家公司所做的，构建集成/中间件软件，因为在很多示例中，提供的 Indy 便捷方法（当时）并未涵盖我们所有的用例，而不仅仅是 GET ，尤其是涉及到 REST Api 时。请注意，上面不是我们当时的实际代码，我不再可以访问它。

我们没有直接使用TIdHttp 类，而是使用了TOurHttp（不是真名），它赋予了许多对我们有用的额外便利方法。我们还发现我们必须对其他方面进行更改和扩展，例如 IgnoreReplies 行为，以适应各种“流氓”REST Api 服务器行为（并非所有这些行为都符合 HTTP 标准），这又是您在大多数用例。

当然，您可以尝试要求 Api 或 HTTP 服务器的提供者更改他们的端，而不是修复您的客户端行为。祝你好运。 ;)

背景阅读

HTTP 协议规范确实允许 GET 请求提交请求正文，但绝大多数实现不允许（或干脆忽略任何此类内容）。这可能是因为从历史上看，绝大多数实现都以浏览器行为为目标或受其驱动，再加上 HTTP 规范不幸在该领域允许一些“回旋余地”这一事实。

这导致了我们今天所处的位置，在撰写本文时（2019 年 1 月），HTTP 规范的相关部分 RFC7231 has this to say about content in a GET request：

GET 请求消息中的有效负载没有定义的语义； 在 GET 请求上发送有效负载正文可能会导致一些现有的 拒绝请求的实现。

即请求内容是允许的，因为它没有被明确禁止，并且它的使用被确认为可能并且有时是预期的（有时只是被拒绝）。但是您不能依赖服务器对此类请求采取任何特定解释（甚至接受）。

这当然无助于处理已决定其特定解释的特定服务器的客户端。通过以这种方式承认不好的做法，HTTP 规范的这种迭代就没有多大用处了。它只是描述了实践中的差异，而不是提供可以测试实现的合规性/准确性的规范。

Answer 2

分配TIdHTTP.Request.Source 属性将不起作用，因为当TIdHTTP.Get() 调用TIdHTTP.DoRequest() 内部传递nil 为其ASource 参数时，Source 将被nil 替换。

因此，要按照您的要求进行操作，您必须直接致电 DoRequest()。但是，它是一个protected 方法，因此您必须使用访问器类来访问它。

例如：

type
  TIdHTTPAccess = class(TIdHTTP)
  end;

var
  QueryData, ReplyData: TStream;
begin
  QueryData := TStringStream.Create('... json data here...', TEncoding.UTF8);
  try
    IdHTTP1.Request.ContentType := 'application/json';
    IdHTTP1.Request.CharSet := 'utf-8';

    //Result := IdHTTP1.Get('http://...');
    ReplyData := TMemoryStream.Create;
    try
      TIdHTTPAccess(IdHTTP1).DoRequest(Id_HTTPMethodGet, 'http://...', QueryData, ReplyData, []);
      ReplyData.Position := 0;
      Result := ReadStringAsCharset(ReplyData, IdHTTP1.Response.Charset);
    finally
      ReplyData.Free;
    end;
  finally
    QueryData.Free;
  end;
end;