Delphi 2007 的异步调用

Question

我基本上想要的是启动AsyncCall 并继续我的代码加载。我有消耗大量时间（600+ms）的接口部分，我想在独立线程中加载此代码。

我尝试使用AsyncCall 来制作这样的东西：

procedure Load;
begin
...
end;

initialization
  AsyncCall(@Load, []); // or LocalAsyncCall(@Load)

然而，这个Load 过程实际上是在主线程中开始的，而不是在新创建的线程中。如何强制将Load 过程加载到MainThread 以外的任何线程中？

我可以创建 TThread 和 Execute 这个，但我想强制 AsyncCall 或 LocalAsyncCall 或 AsyncCall 库中的任何内容使其工作。

感谢您的帮助。

Answer 1

你有没有尝试过这样的事情？：

procedure Load;
begin
  if GetCurrentThreadId <> MainThreadID then
    Beep;
end;

var a: IAsyncCall;

initialization
  a := AsyncCall(@Load, []);
  a.ForceDifferentThread;

ForceDifferentThread() 告诉 AsyncCalls 分配的函数必须 不在当前线程中执行。

Answer 2

问题是您的代码没有保留IAsyncCall 函数返回的AsyncCall 接口。

AsyncCall(@Load, []);
//AsyncCall returns an IAsyncCall interface,
//but this code does not take a reference to it

因此，一旦初始化部分完成，返回的接口的引用计数就会减为零。因此，这释放了实现执行此操作的接口的对象：

destructor TAsyncCall.Destroy;
begin
  if FCall <> nil then
  begin
    try
-->   FCall.Sync; // throw raised exceptions here
    finally
      FCall.Free;
    end;
  end;
  inherited Destroy;
end;

关键行是对Sync 的调用，它强制异步调用执行完成。所有这些都发生在解释您报告的行为的主线程中。

---

解决方案是您只需要通过将IAsyncCall 接口存储在一个变量中来保持它处于活动状态。

var
  a: IAsyncCall;

initialization
  a := AsyncCall(@Load, []);

在实际代码中，您需要确保Load 已完成，然后才能运行任何依赖于Load 的代码。当您的程序达到需要调用Load 的程度时，它必须在IAsyncCall 接口上调用Sync。

所以你可以这样写。

unit MyUnit;

interface

procedure EnsureLoaded;

implementation

uses
  AsyncCalls;

....

procedure Load;
begin
  ....
end;

var
  LoadAsyncCall: IAsyncCall;

procedure EnsureLoaded;
begin
  LoadAsyncCall := nil;//this will effect a call to Sync
end;

initialization
  LoadAsyncCall := AsyncCall(@Load, []);

end.

来自需要Load 运行的其他单位的呼叫EnsureLoaded。或者，或者，从MyUnit 导出的依赖于Load 运行的任何方法调用EnsureLoaded。后一种选择具有更好的封装性。