Delphi的另一个单元中的多线程

Question

我在一个名为 Execution 的单元中有一个数字运算应用程序，它是从主窗体调用的。通常 Execution.pas 中的代码需要连续运行 10-15 次，我正在寻找一种应用多线程的有效方法，以便执行单元上的计算并行运行。简化版代码如下：

其中有一个 Button1 的主窗体：

unit MainForm;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Execution;

type
  TMainForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  end;

var
  MainForm1: TMainForm1;

implementation

{$R *.dfm}

procedure TMainForm1.Button1Click(Sender: TObject);
var
  ExecutionThread: TThread;
  run_ID: integer;
begin
    for run_ID := 0 to 2 do
    begin
        ExecutionThread := TThread.CreateAnonymousThread(
        procedure
        begin
            Execution.CalculateSum;
        end);
        ExecutionThread.FreeOnTerminate := true;
        ExecutionThread.Start;
    end;
end;

end.

Execution.pas 单位：

unit Execution;

interface
uses System.SysUtils, Vcl.Dialogs;

  procedure CalculateSum;
  procedure IncrementSum(var Sum: integer);

implementation

const
  NoOfTimes = 100;
var
  Sum: integer;

procedure CalculateSum;
var
  i: integer;
begin
    Sum := 0;
    for i := 0 to Pred(NoofTimes) do
    begin
        IncrementSum(Sum);
    end;
    ShowMessage('Sum = ' + IntToStr(Sum));
end;

procedure IncrementSum(var Sum: integer);
begin
    Inc(Sum);
    Sleep(10);
end;

end.

如果我执行简化的代码，我会收到三个总和接近 300 的消息，但不是预期的 300（285、287、289），因为所有线程同时更改相同的全局变量 Sum 并且有时增量会重叠。

有没有一种简单的方法可以为每个线程分配不同的内存，以便我得到三条总和为 100 的消息？还是我必须自己硬编码，在每个线程中分配不同的执行变量？

请注意，我拥有的原始应用程序包含数千个变量和记录，因此我正在寻找一种快速的方法来执行此操作而无需显着更改代码（当然，如果有的话）。

提前谢谢你。

Answer 1

不要在没有同步的情况下从多个线程写入同一个变量，否则可能会损坏该变量的数据。

所以不要在你的线程中调用IncrementSum(Sum)Synchronize(IncrementSum(Sum))。

这会强制 IncrementSum 过程在主线程范围内执行，从而防止多个工作线程同时修改该变量，从而导致潜在的数据损坏。

此外，您可能希望避免在每个工作线程的每个循环周期中更新此全局变量。如果您有 10 个工作线程都在等待全局线程更新此全局变量，那么它们最终可能会花费大部分时间等待主线程处理它们的 Synchronize 调用。

例如，也许您应该考虑每 10 个左右周期更新一次这个全局变量。你去和更新全局变量之间的周期数取决于每个周期的完成速度。更快的循环完成更多的循环在更新全局变量之前等待更多的循环，从而减少Synchronize调用的数量，从而减少主线程的负载。

Answer 2

有没有一种简单的方法可以为每个线程分配不同的内存，所以 我收到三条总和为 100 的消息？

有一种非常简单的方法可以为每个线程分配不同的内存并使用相同的声明：使用 threadvar 关键字。

这里是修改的代码：

unit Execution;

interface

uses
  System.SysUtils, Vcl.Dialogs;

procedure CalculateSum;
procedure IncrementSum(var Sum: integer);

implementation

const
  NoOfTimes = 100;
threadvar                // <==== ONLY CHANGE IS HERE
  Sum: integer;

procedure CalculateSum;
var
    i: integer;
begin
    Sum := 0;
    for i := 0 to Pred(NoofTimes) do
    begin
        IncrementSum(Sum);
    end;
    ShowMessage('Sum = ' + IntToStr(Sum));
end;

procedure IncrementSum(var Sum: integer);
begin
    Inc(Sum);
    Sleep(10);
end;

end.

Answer 3

你有没有想过在System.SyncObjs中使用TCriticalSection？

一次只有一个线程可以进入TCriticalSection，所以如果一个线程进入，修改共享变量，然后离开，那么每个线程都会等待其他线程。

如果您将大部分时间花在 TCriticalSection 中，这将无助于扩展，因为您的线程将主要等待对象，但它确实确保只有一个线程正在修改受 TCriticalSection 保护的数据一次。

因此，如果您的代码不断更新共享变量，这将阻止它们发生冲突，但不会真正提供单独线程的好处。但是，如果线程在不修改变量的情况下进行大量计算，那么这允许该代码并行执行。