集合上的 Delphi 'in' 运算符重载

Question

在 Delphi XE2 中，我试图重载记录上的 in 运算符，以允许我检查记录表示的值是否是集合的一部分。我的代码如下所示：

type
  MyEnum = (value1, value2, value3);
  MySet = set of MyEnum;
  MyRecord = record
    Value: MyEnum;
    class operator In(const A: MyRecord; B: MySet): Boolean;
  end;

class operator MyRecord.In(const A: MyRecord; B: MySet): Boolean;
begin
  Result := A.Value in B;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  R: MyRecord;
  S: MySet;
begin
  R.Value := value1;
  S := [value1, value2];
  Button1.Caption := BoolToStr(R in S);
end;

代码编译失败。对于语句R in S，编译器会说：不兼容的类型MyRecord 和MyEnum。

如何在MyRecord 上重载In 运算符，以便R in S 在上述代码中计算为True？

Answer 1

要使 in 运算符起作用，正确的操作数必须是记录类型，因为它是集合运算符而不是二元运算符。在您的情况下，它是左操作数。

所以以下将起作用：

type
  MyRecord = record
    Value: MyEnum;
    class operator In(const A: MyRecord; const B: MySet): Boolean;
  end;

  MyRecord2 = record
    Value: MySet;
    class operator In(const A: MyRecord; const B: MyRecord2): Boolean;
    class operator In(const A: MyEnum; const B: MyRecord2): Boolean;
  end;

class operator MyRecord.In(const A: MyRecord; const B: MySet): Boolean;
begin
  Result := A.Value in B;
end;

class operator MyRecord2.In(const A: MyRecord; const B: MyRecord2): Boolean;
begin
  Result := A.Value in B.Value;
end;

class operator MyRecord2.In(const A: MyEnum; const B: MyRecord2): Boolean;
begin
  Result := A in B.Value;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  R: MyRecord;
  R2: MyRecord2;
begin
  R.Value := value1;
  R2.Value := [value1, value2];

  if R in R2 then;
  if value1 in R2 then;
end;

Answer 2

嗯，您几乎可以这样做，但您可能不想这样做。 AFAIK，类运算符仅适用于它们定义的类（或记录），因此代码中的 R 和 S 都必须是 TMyRecord。通过不明智地使用隐式转换，我们得到以下结果：

unit Unit2;
interface
type
  MyEnum = (value1, value2, value3);
  MySet = set of MyEnum;
  MyRecord = record
    Value: MyEnum;
    ValueSet: MySet;
    class operator Implicit(A: MyEnum): MyRecord;
    class operator Implicit(A: MySet): MyRecord;
    class operator In (Left,Right:MyRecord): Boolean;
  end;

implementation

class operator MyRecord.Implicit(A: MyEnum): MyRecord;
begin
  Result.Value := A;
end;

class operator MyRecord.Implicit(A: MySet): MyRecord;
begin
  Result.ValueSet := A;
end;

class operator MyRecord.In(Left, Right: MyRecord): Boolean;
begin
  Result:= left.Value in Right.ValueSet;
end;
end.

以下内容现在可以编译，甚至可以工作：

procedure TForm1.Button1Click(Sender: TObject);
var
  R: MyRecord;
  S: MyRecord;
begin
  R.Value := value1;
  S := [value1,value2,value3];
  Button1.Caption := BoolToStr(R In S,true);
end;

我相信我们都会同意，它比“BoolToStr(R.Value in S)”要优雅得多。 但是下面的代码也会编译，但是会给出错误的结果：

procedure TForm1.Button1Click(Sender: TObject);
var
  R: MyRecord;
  S: MyRecord;
begin
  R.Value := value1;
  S := [value1,value2,value3];
  Button1.Caption := BoolToStr(S In R,true);
end;

因此，正如 Dorin 所评论的那样，最好只使用沉闷、古板的“BoolToStr(R.Value in S)”。当然，除非您按每行代码获得报酬。以及修复错误的奖励。