如何隐藏 TActionMainMenuBar 图像

Question

我在表单上放置了TActionMainMenuBar，如下所示：

现在，它看起来非常好，除了左边应该放置图像的空白处。由于我不需要在菜单中绘制图像，我怎样才能完全隐藏那个间隙？找不到任何我可以用来隐藏它的属性，而且 Google 查询没有返回关于该主题的结果。

Answer 1

以下示例尝试演示使用您自己的菜单样式需要做些什么。它只是试图从未使用的图像中获得空间，但您可以覆盖绘图的任何方面，请参阅“xpactnctrls.pas”以了解可能的实现。

type
  TBarStyle = class(TXPStyleActionBars)
  public
    function GetControlClass(ActionBar: TCustomActionBar;
      AnItem: TActionClientItem): TCustomActionControlClass; override;
  end;

  TMenuStyle = class(TXPStyleMenuItem)
  protected
    procedure CalcLayout; override;
  public
    procedure CalcBounds; override;
  end;

var
  BarStyle: TBarStyle;

function TBarStyle.GetControlClass(ActionBar: TCustomActionBar;
  AnItem: TActionClientItem): TCustomActionControlClass;
begin
  Result := inherited GetControlClass(ActionBar, AnItem);
  if ActionBar is TCustomActionPopupMenu then
    Result := TMenuStyle;
end;

procedure TMenuStyle.CalcLayout;
begin
  inherited;
  GlyphPos := Point(-16, GlyphPos.Y);
end;

procedure TMenuStyle.CalcBounds;
var
  R: TRect;
begin
  inherited;
  R := TextBounds;
  OffsetRect(R, -16, 0);
  TextBounds := R;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ActionMainMenuBar1.ActionManager.Style := BarStyle;
end;

initialization
  BarStyle := TBarStyle.Create;
  RegisterActnBarStyle(BarStyle);
finalization
  UnregisterActnBarStyle(BarStyle);
  BArStyle.Free;