DataSnap Rest 服务器 windows 服务答案

【问题标题】：DataSnap Rest Server windows ServiceDataSnap Rest 服务器 windows 服务
【发布时间】：2012-10-25 10:09:45
【问题描述】：

我正在尝试构建作为 Windows 服务运行的 DataSnap Rest 应用程序，但向导只有“独立 VCL 应用程序”、“独立控制台应用程序”和“ISAPI 动态链接库”（我是使用 Delphi XE2 企业版）。有人可以帮助我。谢谢。

【问题讨论】：

为什么关闭请求？这个问题怎么没有建设性？

标签： delphi delphi-xe2 datasnap

【解决方案1】：

如果 DataSnap REST 向导可以选择创建 Windows 服务（否则您将如何运行应用程序服务器？）会更方便，但您可以稍微摆弄一下。

我第一次遇到这种情况时，我创建了一个常规 DataSnap REST 服务器作为 VCL 应用程序和一个常规 Windows 服务，并将相关部分从 REST 服务器复制到该服务。只需确保服务的输出目录与 VCL 应用程序的目录相同即可。

服务的 .dpr 可能如下所示：

program Service;

uses
  Vcl.SvcMgr,
  Web.WebReq,
  IdHTTPWebBrokerBridge,
  WebModuleUnit1 in '..\GUI\WebModuleUnit1.pas' {WebModule1: TWebModule},
  ServerMethodsUnit1 in '..\GUI\ServerMethodsUnit1.pas' {ServerMethods1: TDSServerModule},
  ServerContainerUnit1 in '..\GUI\ServerContainerUnit1.pas' {ServerContainer1: TDataModule},
  Unit1 in 'Unit1.pas' {Service1: TService};

{$R *.RES}

begin
  if not Application.DelayInitialize or Application.Installing then
    Application.Initialize;

  if WebRequestHandler <> nil then
    WebRequestHandler.WebModuleClass := WebModuleClass;

  Application.CreateForm(TService1, Service1);
  Application.Run;
end.

服务的主要单元可能如下所示：

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Classes,
  Vcl.Graphics, Vcl.Controls, Vcl.SvcMgr, Vcl.Dialogs,
  IdHTTPWebBrokerBridge, Web.HTTPApp;

type
  TService1 = class(TService)
    procedure ServiceCreate(Sender: TObject);
    procedure ServiceExecute(Sender: TService);
    procedure ServiceStart(Sender: TService; var Started: Boolean);
    procedure ServiceStop(Sender: TService; var Stopped: Boolean);
  private
    FServer: TIdHTTPWebBrokerBridge;
    procedure TerminateThreads;
  public
    function GetServiceController: TServiceController; override;
  end;

var
  Service1: TService1;

implementation

{$R *.DFM}

uses
  //Datasnap.DSService;  // XE2
  Datasnap.DSSession;  // XE3

procedure ServiceController(CtrlCode: DWord); stdcall;
begin
  Service1.Controller(CtrlCode);
end;

{ TService1}

function TService1.GetServiceController: TServiceController;
begin
  Result := ServiceController;
end;

procedure TService1.ServiceCreate(Sender: TObject);
begin
  FServer := TIdHTTPWebBrokerBridge.Create(Self);
end;

procedure TService1.ServiceExecute(Sender: TService);
begin
  while not Terminated do
  begin
    Sleep(1000);
    ServiceThread.ProcessRequests(False);
  end;
end;

procedure TService1.ServiceStart(Sender: TService; var Started: Boolean);
begin
  if not FServer.Active then
  begin
    FServer.Bindings.Clear;
    FServer.DefaultPort := 8080;
    FServer.Active := True;
  end;
end;

procedure TService1.ServiceStop(Sender: TService; var Stopped: Boolean);
begin
  TerminateThreads;
  FServer.Active := False;
  FServer.Bindings.Clear;

  ServiceThread.Terminate;
end;

procedure TService1.TerminateThreads;
begin
  if TDSSessionManager.Instance <> nil then
    TDSSessionManager.Instance.TerminateAllSessions;
end;

end.

【讨论】：