使用 TIdUDPServer 读取数据

Question

我想从通过 UDP 向我的电脑发送数据的电子设备读取数据。我在 Delphi 中编写了一个 UDP 服务器。 EIdSocketError 类中发生异常（失败 #10049）。这是我的代码：

procedure TForm1.Button1Click(Sender: TObject);
begin
   IdUDPServer1.Bindings.add.IP := '192.168.1.1';  //Electronic device ip
   IdUDPServer1.Bindings.add.Port:= 49152;         //Electronic device port   
   IdUDPServer1.OnUDPRead:= UDPRead;
   IdUDPServer1.Active:=True;

end;

procedure TForm1.UDPRead (Sender: TObject; AData: TStream; ABinding: TIdSocketHandle);
var
   bytes_received: integer;
begin
   bytes_received:=AData.size;
end;

我做错了什么？

提前致谢

Answer 1

正如 Keith Miller 所说，您在滥用 Bindings 属性。您正在向服务器添加 2 绑定 - 一个用于端口 0 上的 192.168.1.1，另一个用于端口 0.0.0.0 上的 0.0.0.0。对于要绑定的每个 IP/端口对，您只需调用一次 Bindings.Add()，例如：

var
  Binding: TIdSocketHandle

Binding := IdUDPServer1.Bindings.Add;
Binding.IP := ...;
Binding.Port := ...;

或者：

with IdUDPServer1.Bindings.Add do
begin
  IP := ...;
  Port := ...;
end;

如果你提前设置了DefaultPort属性，那么你可以把上面的简化成这样：

IdUDPServer1.DefaultPort := ...;
IdUDPServer1.Bindings.Add.IP := ...;

话虽如此，套接字错误 10049 是 WSAEADDRNOTAVAIL，这意味着您首先使用了错误的 IP 地址。您需要指定一个属于运行TIdUDPServer 的PC 的IP - 设备将向其发送UDP 数据包的IP。您可以绑定到单个通配符 IP 0.0.0.0（或只是一个空白字符串 ''），它告诉 TIdUDPServer 绑定到所有可用的本地 IP：

IdUDPServer1.DefaultPort := ...;
IdUDPServer1.Bindings.Add.IP := ''; // or: '0.0.0.0' 

或者您可以使用 Indy 的 GStack.LocalAddresses 属性来确定本地可用的 IP，并根据需要为它们单独创建单独的 Bindings。

IdUDPServer1.Bindings.Clear;
IdUDPServer1.DefaultPort := ...;

with GStack.LocalAddresses do
begin
  for I := 0 to Count-1 do
    IdUDPServer1.Bindings.Add.IP := Strings[I];
end;

更新：如果您将服务器绑定到端口 0 以让操作系统选择一个端口，您可以在服务器激活后通过查看 TIdSocketHandle.Port 属性来发现选择了哪个端口：

var
  Binding: TIdSocketHandle
  ListeningPort: TIdPort;

IdUDPServer1.Bindings.Clear;

Binding := IdUDPServer1.Bindings.Add;
Binding.IP := ...;
Binding.Port := 0;
{
or: 
IdUDPServer1.DefaultPort := 0;
Binding := IdUDPServer1.Bindings.Add;
Binding.IP := ...;
}

IdUDPServer1.Active := True;

ListeningPort := Binding.Port;