带字符串参数的 Delphi 程序

Question

我在 Delphi 中处理过程和字符串时遇到了问题。事实是我希望看到输出字符串“1S2S3S4S5S6S”，但实际输出是“1234S5S6”。在调试过程中，它说 S1、S2、S3 和 S6 字符串变量未初始化（S1、S2、S3、S6 是 '' 字符串，S4 和 S5 的值为 'S'）。有人可以向我解释一下吗？代码如下：

program StringTest;

{$APPTYPE CONSOLE}

procedure MyProcedure(S1: String; const S2: String; var S3: String;
                      S4: String; const S5: String; var S6: String;
                      out S7: String);
begin
  S7 := '1' + S1 + '2' + S2 + '3' + S3 + '4' + S4 + '5' + S5 + '6' + S6;
end;

procedure Work;
var
  S: String;
begin
  S := 'S';
  MyProcedure(S, S, S, S, S, S, S);
  writeln(S);
end;

begin
  Work;
  readln;
end.

Answer 1

您的S7 参数被声明为out 参数，因此在调用函数时编译器会将传递的变量设置为空字符串。您正在为所有参数（包括输出参数）传递相同的 S 变量，因此在函数内部使用参数值之前，S 的值会从内存中擦除。

为了进一步详细说明，该过程使用register 调用约定，其中S1..S3 在CPU 寄存器（分别为EAX、EDX 和ECX）和S4..@987654329 中传递@ 而是在堆栈上传递。输入string 变量在其当前值被推入堆栈S4 和S5（S3 和S6 只是指向变量的指针）之后，在值被分配到之前被清除干净S1 和 S2。因此，S1 和 S2 最终为零，S4 和 S5 包含指向擦除前原始 'S' 数据的指针，S3 和 S6 指向 string 变量被抹去。

调试器可以向您展示所有这些操作。如果你在调用MyProcedure()的那一行下断点，然后打开CPU视图，你会看到如下汇编指令：

StringTest.dpr.17: MyProcedure(S, S, S, S, S, S, S);
00405A6C 8B45FC           mov eax,[ebp-$04]  // [ebp-$04] is the current value of S
00405A6F 50               push eax           // <-- assign S4
00405A70 8B45FC           mov eax,[ebp-$04]
00405A73 50               push eax           // <-- assign S5
00405A74 8D45FC           lea eax,[ebp-$04]
00405A77 50               push eax           // <-- assign S6
00405A78 8D45FC           lea eax,[ebp-$04]
00405A7B E8B0EDFFFF       call @UStrClr      // <-- 'out' wipes out S!
00405A80 50               push eax           // <-- assign S7
00405A81 8D4DFC           lea ecx,[ebp-$04]  // <-- assign S3
00405A84 8B55FC           mov edx,[ebp-$04]  // <-- assign S2
00405A87 8B45FC           mov eax,[ebp-$04]  // <-- assign S1
00405A8A E8B9FEFFFF       call MyProcedure

要解决这个问题，您需要使用不同的变量来接收输出：

procedure Work;
var
  S, Res: String;
begin
  S := 'S';
  Proc(S, S, S, S, S, S, Res);
  WriteLn(Res);
end;

或者，将过程更改为一个函数，该函数通过其Result 而不是使用out 参数返回一个新的String：

function MyFunction(S1: String; const S2: String; var S3: String;
                      S4: String; const S5: String; var S6: String): String;
begin
  Result := '1' + S1 + '2' + S2 + '3' + S3 + '4' + S4 + '5' + S5 + '6' + S6;
end;

procedure Work;
var
  S: String;
begin
  S := 'S';
  WriteLn(MyFunction(S, S, S, S, S, S));
end;