返回 self 作为函数结果的问题

Question

我有一个非常简单的 3D 矢量类定义 TVector3D，以及一些用于实现 TVector3D.Normalise 函数的方法。如果我向Normalise 函数传递一个已经标准化的向量，我希望它返回我传递给它的向量。在这里我使用了Result := Self，但我得到了一些疯狂的回报。

控制台应用程序：

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils;

type
  TVector3D = Class
  public
    x : Single;
    y : Single;
    z : Single;
    constructor Create(x : Single;
                       y : Single;
                       z : Single);
    function GetMagnitude() : Single;
    function IsUnitVector() : Boolean;
    function Normalise() : TVector3D;
  end;

  constructor TVector3D.Create(x : Single;
                               y : Single;
                               z : Single);
  begin
    Self.x := x;
    Self.y := y;
    Self.z := z;
  end;

  function TVector3D.GetMagnitude;
  begin
    Result := Sqrt(Sqr(Self.x) + Sqr(Self.y) + Sqr(Self.z));
  end;

  function TVector3D.IsUnitVector;
  begin
    if Self.GetMagnitude = 1 then
      Result := True
    else
      Result := False;
  end;

  function TVector3D.Normalise;
  var
    x : Single;
    y : Single;
    z : Single;
    MagnitudeFactor : Single;
  begin
    if IsUnitVector then
      Result := Self
    else
      MagnitudeFactor := 1/(Self.GetMagnitude);
      x := Self.x*MagnitudeFactor;
      y := Self.y*MagnitudeFactor;
      z := Self.z*MagnitudeFactor;
      Result := TVector3D.Create(x,
                                 y,
                                 z);
  end;

  procedure TestNormalise;
  var
    nonUnitVector : TVector3D;
    unitVector : TVector3D;
    nUVNormed : TVector3D;
    uVNormed : TVector3D;
  begin
  //Setup Vectors for Test
    nonUnitVector := TVector3D.Create(1,
                                      1,
                                      1);
    unitVector := TVector3D.Create(1,
                                   0,
                                   0);
  //Normalise Vectors & Free Memory
    nUVNormed := nonUnitVector.Normalise;
    nonUnitVector.Free;
    uVNormed := unitVector.Normalise;
    unitVector.Free;
  //Print Output & Free Memory
    WriteLn('nUVNormed = (' + FloatToStr(nUVNormed.x) + ', ' + FloatToStr(nUVNormed.y) + ', ' + FloatToStr(nUVNormed.z) + ')');
    nUVNormed.Free;
    WriteLn('uVNormed = (' + FloatToStr(uVNormed.x) + ', ' + FloatToStr(uVNormed.y) + ', ' + FloatToStr(uVNormed.z) + ')');
    uVNormed.Free;
  end;

begin
  try
    TestNormalise;
    Sleep(10000);
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

Normalise 适用于非单位向量，即IsUnitVector 返回 false。但是对于单位向量，例如(1,0,0)，我没有返回自身，而是在之前存在非零的地方得到一个非常低的非零数字的结果，例如(8.47122...E-38,0,0)。

如果我通过调试器运行此程序，并在 Result := Self 行设置一个断点来评估 Self，Self 是 (1,0,0) 但结果变为 (Very Low Number,0,0)。 Very Low Number 每次运行程序时都会发生变化，但似乎总是在 E-38/E-39 附近。

我不明白为什么会这样。为什么会发生这种情况以及如何最好地更改我的 Normalise 函数以避免它。

Answer 1

您当前的TVector3D.Normalise 实现存在一些问题：

• 最后 4 行总是执行，因为在 else 之后没有使用 begin-end 块，
• 因此例程永远不会返回Self，而是始终返回一个新实例，
• 返回的实例的内存可能会泄漏，因为您在函数调用后失去了对它的所有权，
• 当IsUnitVector 返回True 时，MagnitudeFactor 的赋值将被跳过，它将是一个随机值（当前存在于该内存的地址），这就解释了为什么你会得到垃圾。编译器还会警告您：变量MagnitudeFactor 可能尚未初始化。

相反，我会改写如下例程：

function TVector3D.Normalise: TVector3D;
begin
  if not IsUnitVector then
  begin
    x := x / GetMagnitude;
    y := y / GetMagnitude;
    z := z / GetMagnitude;
  end;
  Result := Self;
end;

Answer 2

所有问题的根源在于您使用了一个类，它是一个引用类型。相反，您需要使您的向量成为值类型。这意味着使用record。

在您的代码中，即使您修复了@NGLN 确定的问题，当您开始调用WriteLn 时，您仍然销毁了类的所有实例。

除非你很快掌握这个问题，否则我担心你会继续遇到问题。与您当前的方法相比，切换到使用值类型将使您的编码变得非常简单。

以下是帮助您入门的内容：

type
  TVector3 = record
  public
    class operator Negative(const V: TVector3): TVector3;
    class operator Equal(const V1, V2: TVector3): Boolean;
    class operator NotEqual(const V1, V2: TVector3): Boolean;
    class operator Add(const V1, V2: TVector3): TVector3;
    class operator Subtract(const V1, V2: TVector3): TVector3;
    class operator Multiply(const V: TVector3; const D: Double): TVector3;
    class operator Multiply(const D: Double; const V: TVector3): TVector3;
    class operator Divide(const V: TVector3; const D: Double): TVector3;
    class function New(const X, Y, Z: Double): TVector3; static;
    function IsZero: Boolean;
    function IsNonZero: Boolean;
    function IsUnit: Boolean;
    function Mag: Double;
    function SqrMag: Double;
    function Normalised: TVector3;
    function ToString: string;
  public
    X, Y, Z: Double;
  end;

const
  ZeroVector3: TVector3=();

class operator TVector3.Negative(const V: TVector3): TVector3;
begin
  Result.X := -V.X;
  Result.Y := -V.Y;
  Result.Z := -V.Z;
end;

class operator TVector3.Equal(const V1, V2: TVector3): Boolean;
begin
  Result := (V1.X=V2.X) and (V1.Y=V2.Y) and (V1.Z=V2.Z);
end;

class operator TVector3.NotEqual(const V1, V2: TVector3): Boolean;
begin
  Result := not (V1=V2);
end;

class operator TVector3.Add(const V1, V2: TVector3): TVector3;
begin
  Result.X := V1.X + V2.X;
  Result.Y := V1.Y + V2.Y;
  Result.Z := V1.Z + V2.Z;
end;

class operator TVector3.Subtract(const V1, V2: TVector3): TVector3;
begin
  Result.X := V1.X - V2.X;
  Result.Y := V1.Y - V2.Y;
  Result.Z := V1.Z - V2.Z;
end;

class operator TVector3.Multiply(const V: TVector3; const D: Double): TVector3;
begin
  Result.X := D*V.X;
  Result.Y := D*V.Y;
  Result.Z := D*V.Z;
end;

class operator TVector3.Multiply(const D: Double; const V: TVector3): TVector3;
begin
  Result.X := D*V.X;
  Result.Y := D*V.Y;
  Result.Z := D*V.Z;
end;

class operator TVector3.Divide(const V: TVector3; const D: Double): TVector3;
begin
  Result := (1.0/D)*V;
end;

class function TVector3.New(const X, Y, Z: Double): TVector3;
begin
  Result.X := X;
  Result.Y := Y;
  Result.Z := Z;
end;

function TVector3.IsZero: Boolean;
begin
  Result := Self=ZeroVector3;
end;

function TVector3.IsNonZero: Boolean;
begin
  Result := Self<>ZeroVector3;
end;

function TVector3.IsUnit: Boolean;
begin
  Result := abs(1.0-Mag)<1.0e-5;
end;

function TVector3.Mag: Double;
begin
  Result := Sqrt(X*X + Y*Y + Z*Z);
end;

function TVector3.SqrMag: Double;
begin
  Result := X*X + Y*Y + Z*Z;
end;

function TVector3.Normalised;
begin
  Result := Self/Mag;
end;

function TVector3.ToString: string;
begin
  Result := Format('(%g, %g, %g)', [X, Y, Z]);
end;

这是从我自己的代码库中提取的。我使用的是Double，但如果您真的更喜欢使用Single，那么您可以轻松更改它。

运算符重载的使用使您编写的代码更具可读性。现在你可以写V3 := V1 + V2等等。

这是您的测试代码与此记录的样子：

var
  nonUnitVector: TVector3;
  unitVector: TVector3;
  nUVNormed: TVector3;
  uVNormed: TVector3;

begin
  //Setup Vectors for Test
  nonUnitVector := TVector3.New(1, 1, 1);
  unitVector := TVector3.New(1, 0, 0);

  //Normalise Vectors
  nUVNormed := nonUnitVector.Normalised;
  uVNormed := unitVector.Normalised;

  //Print Output
  WriteLn('nUVNormed = ' + nUVNormed.ToString);
  WriteLn('uVNormed = ' + uVNormed.ToString);
  Readln;
end.

或者如果你想稍微压缩一下：

WriteLn('nUVNormed = ' + TVector3.New(1, 1, 1).Normalised.ToString);
WriteLn('uVNormed = ' + TVector3.New(1, 0, 0).Normalised.ToString);

Answer 3

一些提示：

首先，如果我是你，我实际上会将向量设为记录而不是类，但 YMMV。这将简化很多，因为编译器将管理每个向量的生命周期（您永远不必担心释放事物）。二、

function TVector3D.IsUnitVector;
begin
  if self.GetMagnitude = 1 then
    result := True
  else
    result := False;
end;

通常写成，语法上完全等价，

function TVector3D.IsUnitVector;
begin
  result := GetMagnitude = 1
end;

但即便如此，它也是不正确的。由于您正在处理浮点数，因此您无法可靠地测试相等性。相反，您应该查看幅度是否在某个统一区间内，以便“绒毛”不会干扰。例如，你可以这样做 (uses Math)

function TVector3D.IsUnitVector;
begin
  result := IsZero(GetMagnitude - 1)
end;

第三，您的Normalize 函数如果需要规范化，则返回一个new 向量对象，否则返回same 对象。这很令人困惑。你永远不知道你有多少实例！相反，把它变成一个程序：

procedure TVector3D.Normalize;
var
  norm: single;
begin
  norm := GetMagnitude;
  x := x / norm;
  y := y / norm;
  z := z / norm;
end;

第四，为什么使用single而不是double或real？

第五，正如 NGLN 指出的那样（请支持他的回答！），您忘记了 else 部分中的 begin...end 块 Normalize 函数，所以最后四行 总是 执行！因此，您总是创建一个新的向量实例！不过，我的观点非常重要：您的原始函数“打算”（如果您只是添加 begin...end 块）返回 self 或根据条件创建一个新实例，这是相当可怕的，从那时起您不知道你有多少实例！ （因此，您可能会开始泄漏向量...）