如何防止 TStrings.SaveToFile 创建最终的空行？

Question

我有一个像这样的文件.\input.txt：

aaa
bbb
ccc

如果我使用TStrings.LoadFromFile 读取它并使用TStrings.SaveToFile 将其写回（即使没有应用任何更改），它会在输出文件的末尾创建一个空行。

var
  Lines : TStrings;
begin
  Lines := TStringList.Create;
  try
    Lines.LoadFromFile('.\input.txt');

    //...

    Lines.SaveToFile('.\output.txt');
  finally
    Lines.Free;
  end;
end;

使用TStrings.Text 属性可以观察到相同的行为，该属性将返回一个在其末尾包含一个空行的字符串。

Answer 1

对于 Delphi 10.1 及更高版本，有一个属性 TrailingLineBreak 控制此行为。

当 TrailingLineBreak 属性为 True（默认值）时，Text 属性将在最后一行之后包含换行符。为假时， 那么文本值在最后一行之后将不包含换行符。这也是 可以通过 soTrailingLineBreak 选项控制。

Answer 2

对于 Delphi 10.1 (Berlin) 或更高版本，Uwe 的回答中描述了最佳解决方案。

对于较旧的 Delphi 版本，我通过创建 TStringList 的子类并覆盖 TStrings.GetTextStr 虚函数找到了解决方案，但我很高兴知道是否有更好的解决方案，或者其他人是否发现了问题我的解决方案

界面：

  uses
    Classes;

  type
    TMyStringList = class(TStringList)
    private
      FIncludeLastLineBreakInText : Boolean;
    protected
      function GetTextStr: string; override;
    public
      constructor Create(AIncludeLastLineBreakInText : Boolean = False); overload;
      property IncludeLastLineBreakInText : Boolean read FIncludeLastLineBreakInText write FIncludeLastLineBreakInText;
    end;

实施：

uses
  StrUtils;      

constructor TMyStringList.Create(AIncludeLastLineBreakInText : Boolean = False);
begin
  inherited Create;

  FIncludeLastLineBreakInText := AIncludeLastLineBreakInText;
end;

function TMyStringList.GetTextStr: string;
begin
  Result := inherited;

  if(not IncludeLastLineBreakInText) and EndsStr(LineBreak, Result)
  then SetLength(Result, Length(Result) - Length(LineBreak));
end;

示例：

procedure TForm1.Button1Click(Sender: TObject);
var
  Lines : TStrings;
begin
  Lines := TMyStringList.Create();
  try
    Lines.LoadFromFile('.\input.txt');
    Lines.SaveToFile('.\output.txt');
  finally
    Lines.Free;
  end;
end;