调整 TStringList 大小的更好方法？

Question

我经常发现我需要“调整”TStringList 的大小以恰好容纳 N 个元素，或者向列表中添加额外的空字符串，或者删除不必要的。

在 C++ STL 容器上，我可以使用 resize 方法，但由于它似乎不存在，我通常会这样做（警告：伪代码！）。

list.beginUpdate;

while list.Count < requiredSize do
begin
   list.add('');
end;

while list.Count > requiredSize do
begin
   list.delete(list.count-1);
end;

list.endUpdate;

有没有我忽略的更简单的方法？

Answer 1

从TStringList.Assign的实现来看，没有更好的办法做到这一点。他们基本上是调用Clear，然后将字符串一一添加。

您当然应该将代码放入实用程序方法中：

procedure ResizeStringList(List : TStrings; ANewSize: Integer);
begin
...
end;

或者您可以使用类助手使您的方法看起来是TStringList 本身的一部分。

Answer 2

你问题中的方法是你能做的最好的。如果你使用类助手，你可以让它更干净。例如：

type
  TStringsHelper = class helper for TStrings
    procedure SetCount(Value: Integer);
  end;

procedure TStringsHelper.SetCount(Value: Integer);
begin
  BeginUpdate;
  try
    while Count<Value do
      Add('');
    while Count>Value do
      Delete(Count-1);
  finally
    EndUpdate;
  end;
end;

然后你可以写：

List.SetCount(requiredSize);

Answer 3

Capacity 属性几乎是理想的，因为它将在内部数组中分配正确数量的条目。但是，它有一个不幸的缺点：

• 新分配的内存未初始化。
• 元素数量Strings.Count 未更新。

由于 Delphi 组件架构引用了基本类型 TStrings，因此您可以提供可以支持更有效的调整大小功能的具体子类。例如。考虑以下TList.SetCount 的实现。

procedure TList.SetCount(NewCount: Integer);
var
  I: Integer;
begin
  if (NewCount < 0) or (NewCount > MaxListSize) then
    Error(@SListCountError, NewCount);
  if NewCount > FCapacity then
    SetCapacity(NewCount);
  if NewCount > FCount then
    FillChar(FList^[FCount], (NewCount - FCount) * SizeOf(Pointer), 0)
  else
    for I := FCount - 1 downto NewCount do
      Delete(I);
  FCount := NewCount;
end;

更新Capacity后，如果有新分配的内存，使用FillChar初始化。这比一次添加/删除一项要高效得多。

因此，您可以提供自己独立的 TStrings 子类的具体实现，或者简单地复制 Delphi 的 TStringList，其中包含适当的 SetCount 方法。

尽管如此，我发现这部分代码不太可能会遇到任何性能问题，因此您自己的解决方案包含在适当的实用方法中就足够了。 David's answer 也不错，尽管我个人认为“类助手”功能没有那么有用。实现类助手的“旧方式”更加通用。

Answer 4

var
    List:  TStringList;

Assert(requiredSize >= 0);
if requiredSize > List.Count then
    List.Capacity := requiredSize
else
    while List.Count > requiredSize do
        List.Delete(List.Count - 1);