奇怪的印地重定向帖子

Question

我正在尝试使用 Indy 发送发布请求，但我遇到了一些问题。 在一个表单中，我有 TIdHTTP、一个 TIdSSLIOHandlerSocketOpenSSL 和一个 TIdCookieManager，它们具有以下属性：

TIdHTTP:

IdHTTP1.IOHandler := FSSLIO;
IdHTTP1.AllowCookies := True;
IdHTTP1.HandleRedirects := True;
IdHTTP1.ProxyParams.BasicAuthentication := False;
IdHTTP1.ProxyParams.ProxyPort := 0;
IdHTTP1.Request.ContentLength := -1;
IdHTTP1.Request.Accept := 'text/html, */*';
IdHTTP1.Request.BasicAuthentication := False;
IdHTTP1.Request.UserAgent := 'Mozilla/3.0 (compatible; Indy Library)';
IdHTTP1.HTTPOptions := [hoKeepOrigProtocol, hoForceEncodeParams];
IdHTTP1.OnRedirect := IdHTTP1Redirect;
IdHTTP1.CookieManager := IdCookieManager1;        

TIdSSLIOHandlerSocketOpenSSL：默认值

TIdCookieManager： 默认值

OnRedirect 过程：

Handled := True;

在一个按钮中请求如下：

Params := TStringStream.Create('asdf=asdf',TEncoding.UTF8);    
edtmemo1.Text := IdHTTP1.Post('https://www.detran.mg.gov.br/habilitacao/1-habilitacao-quero-ser-condutor/consultar-resultado-exame-legislacao/-/busca_resultado_exames/', Params);
Params.Free;

但返回错误，响应代码为 301，但奇怪的是该位置与我尝试发送的 url 相同，因此它进入了无限循环。

回应

HTTP/1.1 301 Moved Permanently
Date: Thu, 31 Aug 2017 20:23:32 GMT
Server: Apache
X-Powered-By: PHP/5.3.5
P3P: CP="A politica de privacidade deve estar disponivel no site ou pode ser solicitada via fale conosco."
Set-Cookie: SECCCAKEPHP=e19ttp30m5380ih41qal0gipg2; expires=Sat, 09-Sep-2017 04:23:32 GMT; path=/
Location: https://www.detran.mg.gov.br/habilitacao/1-habilitacao-quero-ser-condutor/consultar-resultado-exame-legislacao/-/busca_resultado_exames/
Cache-Control: max-age=604800
Expires: Thu, 07 Sep 2017 20:23:32 GMT
Content-Length: 0
Content-Type: text/html; charset=utf-8

卷曲测试：

curl -vv -X POST -F 'asdf=asdf' https://www.detran.mg.gov.br/habilitacao/1-habilitacao-quero-ser-condutor/consultar-resultado-exame-legislacao/-/busca_resultado_exames/

我使用 curl 尝试了相同的请求并使用响应代码 200。 知道会发生什么吗？

Answer 1

如果您阅读curl documentation，您会看到-F 选项以multipart/form-data 格式发布数据：

-F, --form

(HTTP) 这让 curl 模拟用户按下提交按钮的填写表单。 这会导致 curl 根据RFC 2388 使用 Content-Type multipart/form-data 发布数据。这可以上传二进制文件等。

但是，您的 TIdHTTP 代码正在发布 application/x-www-form-urlencoded 格式的数据。更重要的是，您没有将 TIdHTTP.Request.ContentType 属性设置为 'application/x-www-form-urlencoded' 以匹配数据。如果您发布TStream，则必须相应地设置ContentType。

TIdHTTP 更喜欢使用TStrings 派生对象（如TStringList）而不是TStream 发布application/x-www-form-urlencoded 数据，因此它可以确保数据被正确编码和格式化，例如：

var
  Params: TStringList;
begin
  ...
  Params := TStringList.Create;
  try
    Params.Add('asdf=asdf'); // <-- DO NOT url-encode the values here!
    // the TStrings version of Post() will set the Request.ContentType
    // to 'application/x-www-form-urlencoded' by default...
    edtmemo1.Text := IdHTTP1.Post('https://www.detran.mg.gov.br/habilitacao/1-habilitacao-quero-ser-condutor/consultar-resultado-exame-legislacao/-/busca_resultado_exames/', Params);
  finally
    Params.Free;
  end;
  ...
end;

TIdHTTP 更喜欢使用 TIdMultipartFormDataStream 对象来发布 multipart/form-data 数据（除非您传递另一个包含预先格式化的 MIME 数据的 TStream）。

所以，要匹配你的 curl 命令发送的内容，试试这个：

uses
  ..., IdMultipartFormData;

var
  Params: TIdMultipartFormDataStream;
begin
  ...
  Params := TIdMultipartFormDataStream.Create;
  try
    Params.AddFormField('asdf', 'asdf', 'utf-8');
    // the TIdMultipartFormDataStream version of Post() will set the
    // Request.ContentType to 'multipart/form-data' with a suitable
    // MIME 'boundary' attribute for you...
    edtmemo1.Text := IdHTTP1.Post('https://www.detran.mg.gov.br/habilitacao/1-habilitacao-quero-ser-condutor/consultar-resultado-exame-legislacao/-/busca_resultado_exames/', Params);
  finally
    Params.Free;
  end;
  ...
end;